为表的每一行运行存储过程

Question

我有一张看起来像这样的桌子

value_1  value_2  value_3
---------------------------
   1        2        3
   4        5        6
   7        8        9
   ...     ...     ...

我需要为此表的每一行运行一个存储过程，例如

foreach value_1, value_2, value_3 from my_table
exec spProcedure value_1, value_2, value_3

有办法做到这一点吗？

Answer 1

您可以使用光标：

DECLARE @value1 INT,
        @value2 INT,
        @value3 INT 

DECLARE cursorElement CURSOR FOR
            SELECT  value_1, value_2, value_2
            FROM    table


OPEN cursorElement
FETCH NEXT FROM cursorElement INTO @value1, @value2, @value3

WHILE ( @@FETCH_STATUS = 0 )
BEGIN
    exec spProcedure @value1, @value2, @value3

    FETCH NEXT FROM cursorElement INTO @value1, @value2, @value3
END         
CLOSE cursorElement
DEALLOCATE cursorElement

Answer 2

DECLARE @Query varchar(MAX);  
select @Query=STUFF((SELECT 'EXEC dbo.spProcedure @value1=' +QUOTENAME(clm1,'''') 
       + ';' from dbo.my_table
FOR XML PATH('')),1,0,'');
EXEC(@Query);

如果您不想对传递值进行任何更改并批量传递所有表值

Answer 3

另一种方式：

DECLARE @MemoryTable table (
    RowID int,
    value_1 int,
    value_2 int,
    value_3 int
)

INSERT INTO @MemoryTable
SELECT ROW_NUMBER() OVER (ORDER BY value_1) AS RowID, * FROM SampleTable


DECLARE @ctr INT
DECLARE @MaxRownum INT

DECLARE @val1 INT
DECLARE @val2 INT
DECLARE @val3 INT


SET @ctr = 1
SET @MaxRownum = (SELECT COUNT(1) FROM @MemoryTable)


WHILE @ctr <= @MaxRownum
BEGIN

    SELECT @val1 = value_1,
           @val2=value_2,
           @val3=value_3
    FROM @MemoryTable
    WHERE RowID = @ctr

    exec spProcedure @val1, @val2, @val3

    SET @ctr = @ctr + 1
END