简单的进程间通信

Question

我想知道Ada提供哪些功能来实现两个正在运行的可执行文件（不是任务）之间的（简单）进程间通信形式？我假设两个可执行文件都是用Ada编写的。

想象一下，一个可执行文件以常规间隔a从传感器读取数据，另一个可执行文件有兴趣以规则间隔b处理这些值。我认为包Ada.Streams.Stream_IO可用于序列化并将传感器数据写入文件，但我不确定如何同步写入（第一个可执行文件）和读取（第二个可执行文件）操作。 pragma Shared_Passive可以用来解决这类问题吗？

Answer 1

这是我自己的问题的解决方案。我发现这个Ada Gem #20描述了pragma Shared_Passive的用法。 GNAT参考手册提供了更多detailed information。

以下源代码演示了在写入器和传感器程序之间交换随机生成的传感器数据。

文件：memory.ads

package Memory is

   pragma Shared_Passive;

   type Sensor_Storage_Type is
      record
         Sequence_Numer : Natural := 0;
         Humidity       : Float   := 0.0;
      end record;

   protected Shared is
      function Read return Sensor_Storage_Type;

      procedure Write (Humidity : Float);
   private
      Current_Value : Sensor_Storage_Type;
   end Shared;

end Memory;

文件：memory.adb

package body Memory is

   protected body Shared is
      function Read return Sensor_Storage_Type is
      begin
         return Current_Value;
      end Read;

      procedure Write (Humidity : Float) is
      begin
         Current_Value.Sequence_Numer := Current_Value.Sequence_Numer + 1;

         Current_Value.Humidity := Humidity;
      end Write;
   end Shared;

end Memory;

文件：sensor_writer.adb

with Ada.Text_IO;
with Ada.Numerics.Float_Random;

with Memory;

procedure Sensor_Writer is
   Generator : Ada.Numerics.Float_Random.Generator;

   package Float_IO is new Ada.Text_IO.Float_IO (Num => Float);

   Random_Humidity : Float;
begin
   while True loop
      Random_Humidity := Ada.Numerics.Float_Random.Random (Generator) * 100.0;

      Memory.Shared.Write (Random_Humidity);

      Ada.Text_IO.Put ("Wrote sensor value: ");
      Float_IO.Put (Random_Humidity, Exp => 0);
      Ada.Text_IO.New_Line;

      delay 5.0;
   end loop;
end Sensor_Writer;

文件：sensor_reader.adb

with Ada.Text_IO;

with Memory;

procedure Sensor_Reader is
   Sensor_Value : Memory.Sensor_Storage_Type;
begin
   while True loop
      Sensor_Value := Memory.Shared.Read;

      Ada.Text_IO.Put_Line ("Read sensor values:");
      Ada.Text_IO.Put_Line ("    Sequence number: " & Sensor_Value.Sequence_Numer'Image);
      Ada.Text_IO.Put_Line ("    Humidity: " & Sensor_Value.Humidity'Image);

      delay 1.0;
   end loop;
end Sensor_Reader;

Answer 2

我认为附件E可以帮助您，更准确地说，E.2.3 Remote Call Interface Library Units。

请记住，并非所有编译器都实现了附件规范。 GNAT确实如此，但对于其他编译器，我不知道。

Answer 3

在流程之间进行IPC的另一个解决方案是在Florist中使用好的旧POSIX IPC，如信号量，共享内存和管道（我在Adacore网站上找不到Florist，所以我想知道这是否仍然保留）。

专业人士：

• 使两个程序在没有网络堆栈的情况下相互通信
• 程序可以使用不同的语言
• 关于POSIX Os的标准

缺点：

• 相当低级的编程
• 需要使用信号量手动进行同步

在Florist中查看的包是POSIX.Generic_Shared_Memory，POSIX.IO和POSIX.Semaphores。

你会在Jacob Sparre Andersen's POSIX pages找到例子