VBA：何时使用函数vs将代码放入主子代码中

Question

我正在尝试自动化将来自不同文件的季度数据编译到单个Excel工作簿中的过程（这需要在每个季度完成）。现在我已经到了一个地步，我想知道是否应该将所有代码保留在主子代码中或者是否应该使用函数。我真的很想听听那些与VBA合作超过几个月并且学习编写高效可读代码的人。

我的代码需要做的第一件事是给我三个日期/日期相关的变量：

• 当前年份，或者在第四季度数据的情况下，前一年
• 根据季度，变量看起来像这样：2018年第四季度的12.31.2018; 2019年第一季度将是03.31.2019。它是保存相关文件的子文件夹名称。
• 本季度，Q1，Q2，Q3或Q4。

请参阅下面的我的代码，如果有什么东西引起你的注意，请改进它。具体来说，我想知道如何命名我的变量（如果你有一个存储年份的变量，你会怎么称呼它？）。此外，Case Else没有必要，对吗？我的意思是month(Date)只能是12个月中的一个。

Sub DetermineDate()

Dim qVar As String
Dim yVar As Integer
Dim fullDate As String

yVar = Year(Date) 'set value here or each time in case statement?

Select Case month(Date)
    Case 1, 2, 3
        qVar = "Q4"
        yVar = Year(Date) - 1
        fullDate = "12.31." & yVar
    Case 4, 5, 6
        qVar = "Q1"
        fullDate = "03.31." & yVar
    Case 7, 8, 9
        qVar = "Q2"
        fullDate = "06.30." & yVar
    Case 10, 11, 12
        qVar = "Q3"
        fullDate = "09.30." & yVar
    Case Else 
        MsgBox "Error"
        Exit Sub

End Select
End Sub

但是，我的问题是：有没有理由不把它放在主要的子？我有这样的想法，关注主要子代码的代码（复制粘贴所有数据）会很好。所以我觉得将代码确定为单独函数中的日期是有意义的。但是，我发现返回多个值并不简单，也不是函数的意图。此外，我只会一次调用这个函数，所以在经过一番思考之后我得出结论，将它放在其他地方可能没有意义。基本上我问的是在使用函数和多个子函数时有什么好的做法。

Answer 1

你可以做这样的事情。

将以下代码添加到VBA编辑器中的新CLASS MODULE中，并确保为该新类命名为clsObject ...

Public Quarter As Integer
Public Year As Integer
Public EndDate As Date

Property Get EndMonth() As Integer
    EndMonth = Month(EndDate)
End Property

Property Get QuarterText() As String
    QuarterText = "Quarter " & Quarter
End Property

Property Get DateString() As String
    DateString = Right("0" & EndMonth, 2) & "." & Day(EndDate) & "." & Year
End Property

现在，将以下代码添加到VBA编辑器中的新MODULE中......

Function DetermineDate(ByVal dtDate As Date) As clsObject
    ' Initialise the current functions return value.
    ' This is only required if the return value is an object that is yet to be assigned a value
    Set DetermineDate = New clsObject

    ' If the year is a simple derivation that is not specific to the month, do it here.
    ' You can also set it here first if it is the default for the vast majority of cases
    ' and then in the case statement, set it to something different if required.
    DetermineDate.Year = Year(dtDate)

    Select Case Month(dtDate)
        Case 1, 2, 3
            DetermineDate.Quarter = 4
            DetermineDate.EndDate = DateSerial(DetermineDate.Year, 12, 31)
            DetermineDate.Year = DetermineDate.Year - 1

        Case 4, 5, 6
            DetermineDate.Quarter = 1
            DetermineDate.EndDate = DateSerial(DetermineDate.Year, 3, 31)

        Case 7, 8, 9
            DetermineDate.Quarter = 2
            DetermineDate.EndDate = DateSerial(DetermineDate.Year, 6, 30)

        Case 10, 11, 12
            DetermineDate.Quarter = 3
            DetermineDate.EndDate = DateSerial(DetermineDate.Year, 9, 30)

        Case Else
            ' For this scenario, you don't need an else but it's here anyway.
            Exit Function

    End Select
End Function

Public Sub CallDetermineDate()
    Dim objResult As clsObject

    Set objResult = DetermineDate(Now)

    Debug.Print "End Date = " & objResult.EndDate
    Debug.Print "Year = " & objResult.Year
    Debug.Print "End Month = " & objResult.EndMonth
    Debug.Print "Quarter = " & objResult.Quarter
    Debug.Print "Quarter Text = " & objResult.QuarterText
    Debug.Print "Date String = " & objResult.DateString
End Sub

...现在运行CallDetermineDate例程，您将看到输出。

我是否正确设置了逻辑设置是不重要的，它试图说明VBA中不同对象的使用以及它们如何挂在一起。

BTW - 一个函数可以返回一个值，sub不能。

在VBA中通常有很多方法可以做，而且有些方法比其他方法更好，但很多时候，它取决于场景以及你需要采取多大程度的解决方案，即边缘情况，数据集的大小，性能与可读性等

上面的方法也可以通过几种不同的方式完成，特别是DetermineDate，所有代码实际上都可以为类模块本身构建一个构造函数（很好），而不是在模块世界中闲逛。同样，有很多方法可以做。

希望它有点解释自己，如果不是，请求离开，但我希望即使只是一点点也有帮助。