如何自动在议程列表中添加文件夹下的所有组织文件？

Question

我正在使用org-mode来编写笔记和组织议程来组织所有笔记，特别是搜索一些信息。按关键字或标签。

C-c a m可以按标签输入搜索某些文件，按关键字搜索C-c a s，org-agenda中的那些功能可以很好地利用，但是，我需要手动将org-file添加到议程列表中。

我在.emacs中添加了一些代码，例如

(setq org-agenda-files (list "path/folder/*.org"))

要么

(setq org-agenda-files (file-expand-wildcards "path/folder/*.org"))

但是，两者都无法自动添加指定到议程列表中的文件夹下的文件，因此我无法在这些组织文件中搜索关键字或标签，除非我打开组织文件并键入Cc [将其添加到议程 - 名单。

如何将文件夹下的所有组织文件自动添加到议程中？

Answer 1

只需命名目录即可。例如，这对我很有用：

(setq org-agenda-files '("~/org"))

还可以看看org-agenda-text-search-extra-files;它允许您添加仅包含在文本搜索中的额外文件。典型值可能是，

(setq org-agenda-text-search-extra-files
      '(agenda-archives
        "~/org/subdir/textfile1.txt"
        "~/org/subdir/textfile1.txt"))

警告：如果在启动Emacs后将文件添加到目录中，则不会包含该文件。

编辑：（2018）要在额外文件列表中包含具有特定扩展名的所有文件，您可以尝试我后来写的以下函数（a more recent version might be available here）。

;; recursively find .org files in provided directory
;; modified from an Emacs Lisp Intro example
(defun sa-find-org-file-recursively (&optional directory filext)
  "Return .org and .org_archive files recursively from DIRECTORY.
If FILEXT is provided, return files with extension FILEXT instead."
  (interactive "DDirectory: ")
  (let* (org-file-list
         (case-fold-search t)         ; filesystems are case sensitive
         (file-name-regex "^[^.#].*") ; exclude dot, autosave, and backupfiles
         (filext (or filext "org$\\\|org_archive"))
         (fileregex (format "%s\\.\\(%s$\\)" file-name-regex filext))
         (cur-dir-list (directory-files directory t file-name-regex)))
    ;; loop over directory listing
    (dolist (file-or-dir cur-dir-list org-file-list) ; returns org-file-list
      (cond
       ((file-regular-p file-or-dir)             ; regular files
        (if (string-match fileregex file-or-dir) ; org files
            (add-to-list 'org-file-list file-or-dir)))
       ((file-directory-p file-or-dir)
        (dolist (org-file (sa-find-org-file-recursively file-or-dir filext)
                          org-file-list) ; add files found to result
          (add-to-list 'org-file-list org-file)))))))

你可以像这样使用它：

(setq org-agenda-text-search-extra-files
      (append (sa-find-org-file-recursively "~/org/dir1/" "txt")
              (sa-find-org-file-recursively "~/org/dir2/" "tex")))

编辑：（2019）正如@ mingwei-zhang的回答和@xiaobing的评论中提到的，来自find-lisp-find-files和find-lisp的directory-files-recursively也提供了这个功能。但请注意，在这些情况下，文件名参数是（贪婪的）正则表达式。所以像(directory-files-recursively "~/my-dir" "org")这样的东西会给你所有的Org文件，包括备份文件（*.org~）。要仅包含*.org文件，您可以使用(directory-files-recursively "~/my-dir" "org$")。

Answer 2

有一种更简单的方法可以对org文件进行递归搜索：

(load-library "find-lisp")
(setq org-agenda-files
   (find-lisp-find-files "FOLDERNAME" "\.org$"))

我在我的org配置中添加了这些行，它只是起作用。

（我不是ELisp或emacs的专家，只是刚从Vim转换到Spacemacs的普通用户）