在 XSLT 中创建列

Question

请帮助使用基本的 XSLT 模板来为每个项目创建列。 输入 XML：

<list>
    <item>
        <name>John</name>
        <image>John Picture</image>
    </item>
    <item>
        <name>Bob</name>
        <image>Bob Picture</image>
    </item>
</list>

输出 HTML：

<table>
    <tr>
        <td>John</td>
        <td>Bob</td>
    </tr>
    <tr>
        <td>John Picutre</td>
        <td>Bob Picture</td>
    </tr>
</table>

Answer 1

如果您希望每个

item

元素都有一列，那么您应该首先选择仅第一个

item

元素下的元素，因为这些元素将代表每行的开始

<xsl:for-each select="item[1]/*">

然后，要构建行，请获取所有与当前所选元素同名的

item

元素下的相关元素

<xsl:apply-templates select="../../item/*[name() = name(current())]" />

虽然如果你像这样定义一个键可能会更容易......

<xsl:key name="items" match="item/*" use="name()" />

然后你会得到具有相同名称的元素，如下所示：

<xsl:apply-templates select="key('items', name())" />

尝试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="html" indent="yes"/>

    <xsl:key name="items" match="item/*" use="name()" />

    <xsl:template match="list">
        <table>
            <xsl:for-each select="item[1]/*">
                <tr>
                    <xsl:apply-templates select="key('items', name())" />
                </tr>
            </xsl:for-each>
        </table>
    </xsl:template>

    <xsl:template match="item/*">
        <td>
            <xsl:value-of select="." />
        </td>
    </xsl:template>
</xsl:stylesheet>

这假设所有元素都存在于每个

item

下（好吧，至少在第一个

item

下）。

Answer 2

您需要发布您编写的XSLT以获得结果，下面是您可以使用的代码：

最终更新脚本：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="1.0">

    <xsl:output indent="yes"/>

    <xsl:template match="list">
        <table>
            <tr>
                <xsl:for-each select="item/name">
                    <td>
                        <xsl:value-of select="."/>
                    </td>
                </xsl:for-each>
            </tr>
            <tr>
                <xsl:for-each select="item/image">
                    <td>
                        <xsl:value-of select="."/>
                    </td>
                </xsl:for-each>
            </tr>
        </table>
    </xsl:template>


</xsl:stylesheet>