我可以使用与 bash 和 zsh 相同的语法循环关联数组的键吗

Question

我想循环关联数组的键，但我希望我的脚本可以在 zsh 和 bash 中工作。有没有一种方法（语法）可以在两者中工作

我知道这个

zsh：

for k in "${(k)array[@]}" do echo $k; done

重击：

for k in "${!array[@]}" do echo $k; done

顺便说一句。我实际上使用 oh-my-zsh，所以我不能真正使用

emulate ksh

这样的东西，因为它会让我的终端崩溃。

Answer 1

您可以将每个实现包装在一个函数中，并仅定义适合当前 shell 的函数：

if [[ $ZSH_VERSION ]]; then
  keys_for_array() {
    local array=$1 dest=$2
    [[ $1 && $2 ]] || { echo "Usage: keys_for_array source-array dest-array" >&2; return 1; }
    : ${(AP)dest::=${(kP)array}}
  }
elif [[ $BASH_VERSION && ! $BASH_VERSION =~ ^([123][.]|4[.][012]) ]]; then
  keys_for_array() {
    [[ $1 && $2 ]] || { echo "Usage: keys_for_array source-array dest-array" >&2; return 1; }
    local -n array=$1 dest=$2
    eval 'dest=( "${!array[@]}" )'
  }
else
  keys_for_array() { echo "ERROR: keys_for_array not available for this shell" >&2; return 1; }
fi

[[ $ZSH_VERSION ]] && typeset -A aa=( 1 one 2 two )
[[ $BASH_VERSION ]] && declare -A aa=( [1]=one [2]=two )
keys_for_array aa aak

declare -p aak

...在 bash 上运行时，输出为：

declare -a aak=([0]="1" [1]="2")

...在 zsh 上运行时，输出为：

typeset -a aak=( 1 2 )

无论哪种情况，您都可以迭代它们：

keys_for_array aa aak
for key in "${aak[@]}"; do
  echo "Key $key has value ${aa[$key]}"
done

---

请注意，上面的两个函数在语法上在两个 shell 中都是有效的。否则，可能需要使用

eval

或

source

仅有条件地拉入它们。就个人而言，我会使用可移植库的 bash 和 zsh 版本创建两个单独的文件，并仅获取适合当前 shell 的文件。

Answer 2

没有足够的声誉点来评论之前的答案，但我可以回答吗？

不要忘记添加“！”获取键与值。

keys_for_array aa aak
for key in "${!aak[@]}"; do
echo "Key $key has value ${aa[$key]}"
done

Answer 3

您还可以将键与关联数组分开声明，作为普通数组。

array=(key1 key2 key3)
declare -A values=([key1]=value1 [key2]=value2 [key3]=value3)

for key in "${array[@]}"
do
  echo "$key -> ${values[$key]}"
done