使用 Nasm Assembler 的 CMPXCHG8B 示例

Question

任何人都可以给我一个非常简单的示例，说明如何将 x86 CMPXCHG8B 指令与 NASM 汇编器一起使用吗？

Answer 1

一切都应该通过注释、标签和代码结构来解释。只需注意

lock

前缀：虽然它使其成为原子性的，但也使其非常慢，因为所有内核都必须在该点同步并确保内存访问中没有冲突。

话又说回来，通常没有合理的理由使用类似

cmpxchg

的指令而不使用

lock

，因为并行进程的原子同步是它优于许多其他解决方案的唯一用法。

对于内存内容的真正简单的非原子“交换”，一组经典的

mov

指令很可能会胜过任何

xchg

，特别是如果您计划提前交换并以适当的延迟读取/写入所有值以免阻塞内存带宽访问。

如果您期望这里有一些关于并行编程同步的教程，那么只需谷歌搜索一些书/等，这不是一个“单一答案”主题，而更像是一个“一本书”主题。

section .text
    global _start       ;must be declared for using gcc
_start:                 ;tell linker entry point

    ; fail example (memory contains different than expected value)

    ; edx:eax = old value (to compare with memory)
    mov eax,'BAD '
    mov edx,'val.'
    ; ecx:ebx = new value to set
    mov ebx,'NEW '
    mov ecx,`val\n`
    ; CMPXCHG8B should fail, old value is different
    lock cmpxchg8b [value]  ; "lock" makes it atomic for multi-core
    ; here edx:eax == `OLD val\n` (the unexpected content of [value])
    
    call displayValue

    ; pass example (memory value as expected)

    ; edx:eax = old value (to compare with memory)
    mov eax,'OLD '
    mov edx,`val\n`
    ; ecx:ebx = new value to set
    mov ebx,'NEW '
    mov ecx,`val\n`
    ; CMPXCHG8B should pass, setting up new value
    lock cmpxchg8b [value]  ; "lock" makes it atomic for multi-core
    
    call displayValue

    ;system call number (sys_exit)
    mov eax, 1
    int 0x80

displayValue:
    mov edx, 8      ;message length
    mov ecx, value  ;message to write
    mov ebx, 1      ;file descriptor (stdout)
    mov eax, 4      ;system call number (sys_write)
    int 0x80        ;call kernel
    ret

section .data

value  db   `OLD val\n`     ; 8 bytes long memory

要构建并运行，请将其另存为“cmpxchg8b.asm”：

nasm -f elf32 cmpxchg8b.asm
ld -m elf_i386 -s -o cmpxchg8b cmpxchg8b.o
./cmpxchg8b

预期输出（当然是在 Linux 盒子上）：

$ ./cmpxchg8bdemo
OLD val                                                                  
NEW val