在Elm中，我如何检测焦点是否会从一组元素中丢失？

Question

假设我有一个包含许多组件的表单。我想从小组中发现一个焦点。因此，应忽略在同一表单上从1输入到另一个输入的焦点。我怎样才能做到这一点？

Answer 1

首先，我们希望能够用一些属性标记组内的每个可聚焦元素，因此当我们切换元素时，我们将知道我们是否在同一组中。这可以通过数据属性来实现。

groupIdAttribute groupId =
    Html.Attributes.attribute "data-group-id" groupId

接下来，我们需要在onBlur事件上解码事件有效负载，以查看target是否与relatedTarget（将获得焦点的那个）不同。并报告变化。 （注意，这里我们通过路径data-group-id引用"dataset", "groupId"）

decodeGroupIdChanged msg =
    Json.Decode.oneOf
        [ Json.Decode.map2
            (\a b ->
                if a /= b then
                    Just a

                else
                    Nothing
            )
            (Json.Decode.at [ "target", "dataset", "groupId" ] Json.Decode.string)
            (Json.Decode.at [ "relatedTarget", "dataset", "groupId" ] Json.Decode.string)
        , Json.Decode.at [ "target", "dataset", "groupId" ] Json.Decode.string
            |> Json.Decode.andThen (\a -> Json.Decode.succeed (Just a))
        ]
        |> Json.Decode.andThen
            (\maybeChanged ->
                case maybeChanged of
                    Just a ->
                        Json.Decode.succeed (msg a)

                    Nothing ->
                        Json.Decode.fail "no change"
            ) 

现在我们可以创建一个onGroupLoss监听器：

onGroupFocusLoss msg =
    Html.Events.on "blur" (decodeGroupIdChanged msg)

并按照这样的方式进行操作：

input [onGroupFocusLoss GroupFocusLoss, groupIdAttribute "a"]

这是一个例子（注意它是用elm-ui构建的，所以有一些额外的代码。）

https://ellie-app.com/3nkBCXJqjQTa1