我的program.exe有时会停止。我已经制作了批处理脚本,用于检查程序是否正在运行,如果不在循环中则启动它。
问题是program.exe启动和运行后循环正在退出。
如果程序仍在运行或需要再次启动,我需要继续运行循环以每5分钟检查一次。
set loopcount=10000
:loop
tasklist /FI "IMAGENAME eq program.exe" /FO CSV > search.log
FINDSTR program.exe search.log > found.log
FOR /F %%A IN (found.log) DO IF %%~zA EQU 0 GOTO end
echo Starting..
start /b C:\_Program\program.exe
:end
del search.log
del found.log
echo Waiting..
timeout /t 300 /nobreak
if %loopcount%==0 goto exitloop
goto loop
:exitloop
pause
如果你必须使用批处理文件,我建议:
在进程崩溃的情况下,计划任务比无限循环更健壮。
运行一次以安排每5分钟重复一次的任务:
schtasks /CREATE /SC DAILY /MO 1 /TN 'Name To Give the Scheduled Task' /TR 'C:\path\to\your\script.bat' /ST 0:00 /RI 5 /DU 24:00
如果您可以使用PowerShell,则等效更简单:
if ($null -eq (ps program -ErrorAction SilentlyContinue)) {
saps C:\_Program\program.exe
}
运行一次以安排每5分钟重复一次的任务:
schtasks /CREATE /SC DAILY /MO 1 /TN 'Name To Give the Scheduled Task' /TR 'powershell -EB C:\path\to\your\script.ps1' /ST 0:00 /RI 5 /DU 24:00
它可能很简单:
@echo off
:repeat
tasklist | findstr /i "program.exe">nul
if not %errorlevel% equ 0 start /b "C:\_Program\program.exe"
timeout /t 10 /nobreak>nul && goto :repeat
这是任务列表,我们使用findstr
来确定errorlevel
,如果不是0
启动程序,timeout
10秒并重复,不需要外部文件。
这是一个测试的例子。实现连续检查(循环)进程“WinRAR.exe”的存在(作为检查应用程序的一个例子);所以你可以改变路径和进程名称来检查。
@echo off
Set "MyApplication=%Programfiles%\WinRAR\WinRAR.exe"
Set "MyProcess=WinRAR.exe"
Color 9B
Title Check Running process "%MyProcess%"
mode con cols=75 lines=2
:Loop
cls
tasklist /nh /fi "imagename eq %MyProcess%" 2>nul |find /i "%MyProcess%" >nul
If not errorlevel 1 (Echo "%MyProcess%" is running) else (start "" "%MyApplication%")
ping -n 60 127.0.0.1 >nul
goto Loop