判断单元格是否包含数据验证

Question

我正在编写一个 VBA 代码，它会遍历一系列单元格，检查每个单元格是否具有数据验证（下拉菜单），如果没有，则从另一张纸上的列表中为其分配一个数据。

我目前在检查当前单元格是否已进行数据验证的行上遇到问题。我收到错误 1004“未找到单元格”。

Sub datavalidation()

    Dim nlp As Range
    Dim lrds As Long
    Dim wp As Double
    Dim ddrange As Range

    Sheets("DataSheet").Select

        lrds = ActiveSheet.Range("A1").Offset(ActiveSheet.rows.Count - 1, 0).End(xlUp).Row

        Set nlp = Range("I3:I" & lrds)

        For Each cell In nlp

    'error on following line

            If cell.SpecialCells(xlCellTypeSameValidation).Cells.Count < 1 Then
                wp = cell.Offset(0, -8).Value

                Set ddrange = ddrangefunc(wp)

            End If

        Next

End Sub

有什么想法吗？ 谢谢你

Answer 1

我知道这个问题已经很老了，但由于它是在谷歌搜索“excel vba 检查单元格是否具有验证”时出现的，所以我想我应该持保留态度。

如果您调用

Range

的

SpecialCells

对象仅代表单个单元格，则将扫描整个工作表以查找匹配项。如果你的数据量非常大，之前答案中提供的方法可能会变得有点慢。

因此，这是一种更有效的方法来检查单个单元是否具有验证：

Function HasValidation(cell As Range) As Boolean
    Dim t: t = Null

    On Error Resume Next
    t = cell.Validation.Type
    On Error GoTo 0

    HasValidation = Not IsNull(t)
End Function

Answer 2

Dim cell As Range, v As Long

For Each cell In Selection.Cells
    v = 0
    On Error Resume Next
    v = cell.SpecialCells(xlCellTypeSameValidation).Count
    On Error GoTo 0

    If v = 0 Then
        Debug.Print "No validation"
    Else
        Debug.Print "Has validation"
    End If
Next

Answer 3

如果你只想测试activecell，那么：

Sub dural()
    Dim r As Range
    On Error GoTo noval
    Set r = Cells.SpecialCells(xlCellTypeAllValidation)
    If Intersect(r, ActiveCell) Is Nothing Then GoTo noval
    MsgBox "Active cell has validation."
    Exit Sub
noval:
    MsgBox "Active cell has no validation."
    On Error GoTo 0
End Sub

Answer 4

寻找一种方法来处理这个问题，避免下一步继续出现错误。 这就是我实现它的方式：

Option Explicit
' https://stackoverflow.com/questions/18642930/determine-if-cell-contains-data-validation
' Use this if you want to omit doing something to the cell added: http://dailydoseofexcel.com/archives/2007/08/17/two-new-range-functions-union-and-subtract/
Sub ValidationCells()

    Dim theSheet As Worksheet
    Dim lastCell As Range
    Dim validationRange As Range
    Dim validationCell As Range
    
    Application.EnableEvents = False ' optional
    
    Set theSheet = ThisWorkbook.Worksheets(1)
    
    theSheet.Unprotect ' optional
    
    ' Add a cell with a value and some validation to bypass specialcells error
    Set lastCell = theSheet.Cells(1, theSheet.Cells.Columns.Count)
    With lastCell
        .Value2 = 1
        .Validation.Add xlValidateWholeNumber, xlValidAlertInformation, xlEqual, "1"
    End With
    
    ' If usedrange is greater than 1 (as we added a single cell previously)
    If theSheet.UsedRange.Rows.Count > 1 Or theSheet.UsedRange.Columns.Count > 1 Then
    
        Set validationRange = theSheet.UsedRange.SpecialCells(xlCellTypeAllValidation)
        
        MsgBox validationRange.Address
        
        For Each validationCell In validationRange
            If validationCell.Address <> lastCell.Address Then
                MsgBox validationCell.Address
            End If
        Next validationCell
        
    End If
    
    lastCell.Clear
    
    Set validationRange = Nothing
    Set lastCell = Nothing
    
    theSheet.Protect ' optional
    
    Application.EnableEvents = True ' optional
    

End Sub

Answer 5

此外，如果您想获得验证

Source

，您可以使用以下...

Dim cell as Range
Dim rng as Range
Set rng = Range("A1:A10") 'enter your range

On Error Resume Next 'will skip over the cells with no validation

For Each cell In rng
    msgbox cell.Validation.Formula1
Next cell

Answer 6

大约 4 年后，我也在寻找细胞验证。结合这里的一些答案，这就是我得出的结论：

Option Explicit

Public Sub ShowValidationInfo()

    Dim rngCell             As Range
    Dim lngValidation       As Long

    For Each rngCell In ActiveSheet.UsedRange

        lngValidation = 0

        On Error Resume Next
        lngValidation = rngCell.SpecialCells(xlCellTypeSameValidation).Count
        On Error GoTo 0

        If lngValidation <> 0 Then
            Debug.Print rngCell.Address
            Debug.Print rngCell.Validation.Formula1
            Debug.Print rngCell.Validation.InCellDropdown
        End If
    Next

End Sub

Answer 7

Function isValidated(ByVal Cell as Range) as Boolean
    On Error Resume Next
    isValidated = Not isEmpty(Cell.Validation.Type)
End Function

Answer 8

这对我有用

Sub test()
    On Error Resume Next
        If ActiveCell.SpecialCells(xlCellTypeSameValidation).Cells.Count < 1 Then
            MsgBox "validation"
        Else
            MsgBox "no Validation"
        End If
    On Error GoTo 0
End Sub

Answer 9

Piggy 放弃了 Ricardo 的答案，采用了非错误处理方法。

Function HasValidation(c As Range) As Boolean

Dim vRange As Range, vCell As Range

HasValidation = False
Set vRange = UsedRange.SpecialCells(xlCellTypeAllValidation)

For Each vCell In vRange

    If vCell.Address = c.Address Then
    
        HasValidation = True
        Exit Function
    
    End If
    
Next vCell

End Function