根据TreeView列表中检查的项目创建TabSheet和框架

Question

• 我的表单上有一个TreeView，是从DB table填充的。
• 该列表当前有22个项目，所有项目均为checkboxes /可以检查。

TreeView在具有form和预制PageControl的TabSheet上，并且所有其他TabSheets是动态创建的，并为其分配了Frames。

用于在运行时创建新的TabSheet的当前代码：

procedure TForm1.Button2Click(Sender: TObject);
var
  aTab: TTabSheet;
begin
  aTab := TTabSheet.create(self);
  aTab.Name := 'tabProduct_' + IntToStr(PageControl1.PageCount+1);
  aTab.PageControl := PageControl1;
  aTab.Caption := 'Product ' + IntToStr(aTab.PageIndex);
  LoadFrame(aTab.PageIndex);
end;

LoadFrame过程的代码是：

procedure TForm1.LoadFrame(const index: integer);
var
  aClassName: string;
  aFrameClass : TFrameClass;
  I: Integer;
begin
  if index >= 50 then
    raise Exception.create('Max product count reached');
  if index >= Length(frames) then
    SetLength(frames, index+1);

  if assigned(frames[curIndex]) then frames[curIndex].hide;

  if not assigned(frames[index]) then
  begin
    if index = 0 then
      aClassname := 'TframeClient' // client
    else
      aClassname := 'TframeProdus'; // anything over pageindex 0 is a product
    aFrameClass := TFrameClass(GetClass(aClassname));
    if not assigned(aFrameClass) then
      raise exception.createfmt('Could not find class %s', [aClassname]);
    frames[index] := aFrameClass.Create(self);
    frames[index].name := 'myframe' + IntToStr(index); // unique name
    frames[index].parent := PageControl1.pages[index];
    frames[index].align := alClient;
  end;
  frames[index].show;
  curIndex := Index;
end;

其他相关代码：

type
  TFrameArray = array of TFrame;

<...>

  private
    { Private declarations }
    curIndex: integer;
    frames: TFrameArray;
    procedure LoadFrame(const index: integer);
  public
    { Public declarations }
  end;

  TFrameClass = class of TFrame;

<...>

假设我选中TreeView列表中项目1、5和13旁边的框。

• 我如何确定并修改Button2代码以仅基于我在TreeView中检查的项目为/创建TabSheets及其框架？

Answer 1

与此同时，设法弄清楚了这种方法，似乎效果很好

procedure TForm1.Button2Click(Sender: TObject);
var
  aTab: TTabSheet;
  i: Integer;
begin
   for i:=1 to TreeView1.Items.Count do
begin
   if TreeView1.Items[i-1].Checked then
    begin
      aTab := TTabSheet.create(self);
      aTab.Name := 'tabProduct_' + IntToStr(PageControl1.PageCount+1);
      aTab.PageControl := PageControl1;
      aTab.Caption := TreeView1.Items.Item[i-1].Text;
      LoadFrame(aTab.PageIndex);
    end;
  end;
end;