如何在VB中获得上个月的开始和结束

Question

我试图创建一些VB代码，将获得上个月的开始和结束。我能够在当前这个月只是：

Month(DateValue(Now))

哪个会返回3.从那里我可以带走1给我2个意思二月。这很好，但是当我在1月份，我重复这个并且它给我零 - 我的代码将失败。谁知道如何获得前几个月的开始和结束日呢？

谢谢

Answer 1

上个月的第一天始终为1，要获取上个月的最后一天，请使用DateSerial为0：

''Today is 20/03/2013 in dd/mm/yyyy
DateSerial(Year(Date),Month(Date),0) = 28/02/2013 
DateSerial(Year(Date),1,0) = 31/12/2012 

您可以像上面这样从第一天开始：

LastDay = DateSerial(Year(Date),Month(Date),0)
FirstDay = LastDay-Day(LastDay)+1

另见：How to caculate last business day of month in VBScript

Answer 2

我有第一天和最后一天的类似公式

这个月的第一天

FirstDay = DateSerial(Year(Date),Month(Date),1)

下个月的零日是该月的最后一天

LastDay = DateSerial(Year(Date),Month(Date)+ 1,0) 

Answer 3

firstDay = DateSerial(Year(DateAdd("m", -1, Now)), Month(DateAdd("m", -1, Now)), 1)
lastDay = DateAdd("d", -1, DateSerial(Year(Now), Month(Now), 1))

这是另一种方法，但我认为Remou的版本看起来更干净。

Answer 4

这对我来说可靠。

Dim defDate1 As Date, defDate2 As Date

'** Set default date range to previous month
defDate1 = CDate(Month(Now) & "/1/" & Year(Now))
defDate1 = DateAdd("m", -1, defDate1)
defDate2 = DateAdd("d", -1, DateAdd("m", 1, defDate1))

Answer 5

试试这个以数字形式获取月份：

Month(DateAdd("m", -3, Now))

它将在12月给你12。

所以在你的情况下你会使用Month(DateAdd("m", -1, Now))减去一个月。

Answer 6

只是为了添加@Fionnuala所说的内容，可以使用以下功能。这些甚至适用于闰年。

'If you pass #2016/20/01# you get #2016/31/01#
Public Function GetLastDate(tempDate As Date) As Date
    GetLastDate = DateSerial(Year(tempDate), Month(tempDate) + 1, 0)
End Function

'If you pass #2016/20/01# you get 31
Public Function GetLastDay(tempDate As Date) As Integer
    GetLastDay = Day(DateSerial(Year(tempDate), Month(tempDate) + 1, 0))
End Function

Answer 7

Public Shared Function GetFOMPrev(ByVal tdate As Date) As Date
    Return tdate.AddDays(-(tdate.Day - 1))
End Function

Public Shared Function GetEOMPrev(ByVal tdate As Date) As Date
    Return tdate.AddDays(-tdate.Day)
End Function

用法：

'Get End of Month of Previous Month - Pass today's date
EOM = GetEOMPrev(Date.Today)

'Get First of Month of Previous Month - Pass date just calculated
FOM = GetFOMPrev(EOM)

Answer 8

试试这个

First_Day_Of_Previous_Month = New Date(Today.Year, Today.Month, 1).AddMonths(-1)

Last_Day_Of_Previous_Month = New Date(Today.Year, Today.Month, 1).AddDays(-1)