基于属性值修改现有的XML元素

Question

我想基于使用XSLT以下属性值来更新XML值是输入和输出XML

在这个例子中，我想在输入字符串追加硬编码值。

输入XML

<MyInfo isSurname="true">
    <name sysid="0">Google</name>
</MyInfo>

输出XML

<MyInfo isSurname="true" surname="Drive">
    <name sysid="0">Google Drive</name>
</MyInfo>

对于每一个输入的名字姓将是相同的。所以当属性isSurname是真的，我们需要添加“驱动器”为姓

Answer 1

让我们把你的输入XML在如下根节点：

<?xml version="1.0" encoding="UTF-8"?>
<Root>
   <MyInfo isSurname="true">
       <name sysid="0">Google</name>
   </MyInfo>
</Root>

在XSLT 1.0的溶液，可以是：

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
</xsl:template>

<xsl:template match="/Root/MyInfo">
    <xsl:choose>
        <xsl:when test="@isSurname = 'true'">
            <xsl:copy>
                <xsl:attribute name="surname">
                    <xsl:value-of select="'Drive'" />
                </xsl:attribute>
                <xsl:apply-templates select="@*|node()" />
            </xsl:copy>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy>
                <xsl:apply-templates select="@*|node()" />
            </xsl:copy>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="/Root/MyInfo[@isSurname = 'true']/name/text()">
    <xsl:value-of select="concat(.,' Drive')" />
</xsl:template>

有根据的isSurname属性的检查。

• 如果是true，然后通过你给出的输出XML将被填充。
• 如果是false，然后输入将XML作为它显示出来。

Answer 2

这将为你的短例如工作 - 不知道那些是要应用的一般规则：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="@isSurname[.='true']">
    <xsl:copy/>
    <xsl:attribute name="surname">Drive</xsl:attribute>
</xsl:template>

<xsl:template match="name[../@isSurname='true']/text()">
    <xsl:copy/>
    <xsl:text> Drive</xsl:text>
</xsl:template>

</xsl:stylesheet>