有没有办法将子程序的打印输出捕获到变量，所以我可以将它发送到stderr？

Question

假设我们有：

sub test {
        print "testing\n";
}

如果有一种情况我想让它打印到stderr而不是stdout，有没有办法我可以调用子程序来做到这一点？或者我可以将输出捕获到变量然后使用警告？我对perl很新。

Answer 1

就在这里。 print将其输出发送到“选定的”文件句柄，通常是STDOUT。但是Perl提供了select功能供您更改。

select(STDERR);
&test;           # send output to STDERR
select(STDOUT);  # restore default output handle

select函数返回先前选择的文件句柄，因此您可以捕获它并在以后恢复它。

my $orig_select = select(STDERR);
&test;
select($orig_select);

Answer 2

通过local()进行Perl的动态范围设计并不经常使用，但这对我来说是一个很好的应用：

test(); # to stdout
{
    open(local *STDOUT, ">&STDERR") or die "dup out to err: $!";
    test(); # to stderr, locally calling it "STDOUT"
}
test(); # to stdout again

在上面的块中调用test() - 以及test()本身可能调用的任何内容 - 将STDOUT动态地限制为您的STDERR副本。当控件离开块时，即使通过die()ing，STDOUT也将恢复为块之前的任何值

广义：

sub out2err(&) {
  my $user_block = shift;
  open(local *STDOUT, ">&STDERR") or die $!;
  $user_block->();
}

test();             # to stdout
out2err { test() }; # to stderr
test();             # to stdout

Answer 3

同时，您还可以“将子程序的打印输出捕获到变量”。

只需将标量参考传递给open：

#! /usr/bin/env perl
use common::sense;
use autodie;

sub tostring (&) {
  my $s;
  open local *STDOUT, '>', \$s;
  shift->();
  $s
}

sub fake {
  say 'lalala';
  say 'more stuff';
  say 1 + 1, ' = 2';
  say for @_;
}

for (tostring { fake(1, 2, 3) }) {
  s/\n/\\n/g;
  say "Captured as string: >>>$_<<<";
}

输出：

Captured as string: >>>lalala\nmore stuff\n2 = 2\n1\n2\n3\n<<<

Answer 4

这对我有用

local *STDOUT;
open(STDOUT, ">", \$Result);
&test();
print $Result;