如何计算非空白单元格（包含文本的单元格）的数量？

Question

我想计算包含某个范围内任何内容的单元格。 任何包含文本、数字或其他内容的单元格都应该在我的结果单元格中加一。

我发现了这个功能，

countif(range; criteria)

但这对我不起作用，因为我不知道在标准中输入什么。我该怎么做？

Answer 1

您可以传递

"<>"

（包括引号）作为

criteria

的参数。 这基本上是说，只要它不为空/空白，就计算它。 我相信这就是你想要的。

=COUNTIF(A1:A10, "<>") 

否则你可以按照斯科特的建议使用

CountA

Answer 2

COUNTIF 函数将仅对包含指定范围内的数字的单元格进行计数。

COUNTA(range) 将计算参数列表中的所有值。即使文本条目和数字包含长度为 0 的空字符串，也会对其进行计数。

示例： A7 中的功能 =COUNTA(A1:A6)

范围：

A1

A2b

A3香蕉

A4 42

A5

A6

A7 4 -> 结果

Google 电子表格函数列表包含所有可用函数的列表，以供将来参考https://support.google.com/drive/table/25273?hl=en。

Answer 3

标准应该是

"?*"

而不是

"<>"

，因为后者也会计算包含空结果的公式，例如“”

所以最简单的公式是

=COUNTIF(Range,"?*")

Answer 4

样本文件

注：

• 尝试找到计算非空白单元格（

  =""

  是空白单元格）的公式，而无需使用

  data

  两次。 goolge-spreadhseet的解决方案：

  =ARRAYFORMULA(SUM(IFERROR(IF(data="",0,1),1)))

  。对于 excel

  ={SUM(IFERROR(IF(data="",0,1),1))}

  应该可以工作（在公式中按 Ctrl+Shift+Enter）。

Answer 5

如果您的单元格具有类似

=""

的内容并且不想对它们进行计数，则必须通过类似

的公式从单元格总数中减去空单元格数

=row(G101)-row(G4)+1-countblank(G4:G101)

如果是二维数组，那就是

=(row(G101)-row(A4)+1)*(column(G101)-column(A4)+1)-countblank(A4:G101)

在谷歌文档上测试。

Answer 6

COUNTIF

功能可以统计特定条件下的单元格 其中

COUNTA

将计算包含任何值的所有单元格

示例：

A7

中的函数：

=COUNTA(A1:A6)

范围：

A1| a

A2| b

A3| banana

A4| 42

A5|

A6|

A7| 4 (result)

Answer 7

这有效。

=ArrayFormula(SUM(IF(ISTEXT(将您的文本范围与任何内容混合),1,0),1))

1. IsText(range) 查看您的数据，并为每个文本单元格返回 True，为每个非文本单元格返回 false。我认为这些会返回到数据表/数组中。请参阅步骤 4。
2. If(IsText(range),1,0) 从步骤 1 中 IsText 返回的数组/表中获取 True/False 值，并将 True 转换为 1，将 False 转换为 0，作为真整数，而不是字符串。
3. Sum(range) 然后对 1（True/单元格完全是文本）进行总计并忽略 0（False/单元格不完全是文本）。
4. 由于某种原因，需要使用 ArrayFormula 将所有单元格的总和返回到一个单元格中，而不是将所有单元格的总和返回到相同大小的表格中。我不知道。如果有了解的人可以补充一下，我将不胜感激。

好机会。

Answer 8

要计算其中包含任何内容的任何单元格（包括任何文本或数值，以及具有文本或数字或空白结果的公式），然后使用：

=COUNTIF(A1:A10, "<>")

或

=COUNTA(A1:A10)

---

仅计算具有非空白值的单元格（包括文本或数值，或具有数字或文本值的公式，但不包括具有空白结果的公式），即：单元格值长于零个字符，然后使用:

=SUMPRODUCT(--(LEN(A1:A10)>0))

或

=COUNTA(FILTER(A1:A10, A1:A10 <> ""))

---

仅计算具有文本（字母数字）值的单元格，然后使用：

=COUNTIF(A1:A10,"?*")

仅计算具有数值的单元格，然后使用：

=COUNT(A1:A10)

要计算所有空白单元格（包括没有值的单元格和公式结果为空的单元格），然后使用：

=COUNTBLANK(A1:A10)