避免在Haskell中重复实例声明

Question

我的问题似乎与this密切相关。

我的代码解析yaml文件，重新排列对象并写入一个新的yaml文件。它运作得非常好，但其中有一个特别难看的部分。

我必须将我的数据结构声明为FromJson和ToJson的实例，如下所示：

instance FromJSON Users where
  parseJSON = genericParseJSON (defaultOptions { fieldLabelModifier = body_noprefix })
instance ToJSON Users where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix })

问题是我必须重复8个左右的其他情况：

instance FromJSON Role where
  parseJSON = genericParseJSON (defaultOptions { fieldLabelModifier = body_noprefix })
instance ToJSON Role where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix })

...
...

我无法弄清楚如何避免这种重复。是否有一些方法只声明两个函数（例如在一个新类中），并让所有这些数据类型派生自它？

解决方案（另见dfeuer接受的答案）：

我个人喜欢这个解决方案。你需要添加

{-# language DerivingVia #-}
{-# language UndecidableInstances #-}

newtype NP a = NP {unNP::a} 

instance (Generic a, GFromJSON Zero (Rep a)) => FromJSON (NP a) where
  parseJSON = fmap NP . genericParseJSON 
    (defaultOptions { fieldLabelModifier = body_noprefix })

instance (Generic a, GToJSON Zero (Rep a)) => ToJSON (NP a) where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix }) . unNP

然后你可以声明这样的类型：

data User = User { ... } deriving (Show, Generic)
                         deriving FromJSON via (NP User)
                         deriving ToJSON via (NP User)

Answer 1

这就是相当新的DerivingVia扩展所用的内容。

{-# language DerivingVia #-}

newtype NP a = NP {unNP::a}

instance (Generic a, GFromJSON Zero (Rep a)) => FromJSON (NP a) where
  parseJSON = fmap NP . genericParseJSON 
    (defaultOptions { fieldLabelModifier = body_noprefix })

instance (Generic a, GToJSON Zero (Rep a)) => ToJSON (NP a) where
  toJSON = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix }) . unNP

现在，你可以写

deriving via (NP User) instance FromJSON User

要么

data User = ...
  deriving Generic
  deriving (FromJSON, ToJSON) via (NP User)

等等。

这并没有为左下方的答案节省太多。但是，一旦你添加了toEncoding的定义，它开始看起来值得。

警告：我没有测试过这个。

Answer 2

喜欢，

noPrefixParseJSON :: (Generic a, GFromJSON Zero (Rep a)) => Value -> Parser a
noPrefixParseJSON
    = genericParseJSON (defaultOptions { fieldLabelModifier = body_noprefix })
noPrefixToJSON :: (Generic a, GToJSON Zero (Rep a)) => a -> Value
noPrefixToJSON
    = genericToJSON (defaultOptions { fieldLabelModifier = body_noprefix })

instance FromJSON User where parseJSON = noPrefixParseJSON
instance ToJSON User where toJSON = noPrefixToJSON
instance FromJSON Role where parseJSON = noPrefixParseJSON
instance ToJSON Role where toJSON = noPrefixToJSON
...

当然这仍然是重复的，但我会说这不再是任何担忧的原因。

Answer 3

如果明确声明所有这些类似的实例证明太繁重，也许你可以用phantom type参数化你的数据类型

data User x = User { aa :: Int, bb :: Bool } deriving Generic

data Role x = Role { xx :: Int, dd :: Bool } deriving Generic

然后定义一个“标记”数据类型

data Marker

此数据类型仅用作挂起实例的挂钩，如下所示

{-# language UndecidableInstances #-}
instance (Generic (f Marker), GFromJSON Zero (Rep (f Marker))) => FromJSON (f Marker) where 
    parseJSON = noPrefixParseJSON

它值得吗？可能不是，因为数据类型的定义变得更加复杂。另一方面，您可以通过更改标记来更改序列化的各个方面，从而获得一些灵活性。