在下一个空行中将数据从一个工作表复制到另一个工作表

Question

Hy专家，我正在使用两张excel表。一个是输入，第二个是数据库。在输入表中，我想在单击数据库表上的按钮后复制整个数据。我使用的宏很好用。但不是粘贴下一个空行的数据，而是重新开始写入现有数据。这是toataly错误的概念。我正在使用这个宏。

Sub copydate()
'
' copydate Macro
'

'
    Range("E1:J1").Select
    Selection.Copy
    Sheets("DATABASE").Select
    Range("A2").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Range("A2").Select
    Application.CutCopyMode = False
    Selection.NumberFormat = "m/d/yyyy"
    Range("A2:A75").Select
    Selection.FillDown
    Sheets("INPUT SHEET").Select
    Range("A3:J77").Select
    Selection.Copy
    Sheets("DATABASE").Select
    Range("B2").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Selection.Columns.AutoFit
    Columns("B:B").Select
    Application.CutCopyMode = False
    With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlBottom
        .WrapText = False
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
End Sub

我正在使用这些床单。

我怎样才能解决这个问题。提前致谢。

Answer 1

为了帮助您，我需要做出以下假设：

1每次在添加要复制的新数据之前清除INPUT SHEET中的数据

2您想要从INPUT SHEET中复制A到J列的整个范围（您的现有代码似乎表明了这一点）

3我假设您希望将INPUT SHEET中单元格E1的日期复制到粘贴到DATABASE表格中的所有新数据旁边的A列。尝试使用现有数据输出代码 - 如果它不起作用则调整代码尽可能地适合。学习的唯一方法是尝试，再试一次......

Option Explicit

Sub CopyToDatabase()
Dim LastInput As Long, PasteRow As Long, LastRow As Long

'Find the last row of data to copy
LastInput = Sheets("INPUT SHEET").Range("A3").End(xlDown).Row

'Find the row to paste the new data to
If Sheets("DATABASE").Range("A2") <> "" Then
    PasteRow = Sheets("DATABASE").Range("A2").End(xlDown).Row + 1
    Else
    PasteRow = 2
End If

'Copy the data
Sheets("INPUT SHEET").Range("A3:J" & LastInput).Copy _
Sheets("DATABASE").Range("B" & PasteRow)

'Find the last row of newly copied data
LastRow = Sheets("DATABASE").Range("B2").End(xlDown).Row

'Put the date next to the newly copied data
Sheets("DATABASE").Range("A" & PasteRow & ":A" & LastRow).Value _
= Sheets("INPUT SHEET").Range("E1").Value

End Sub