Windows批处理脚本，以查看是否打开了一系列服务器/端口？

Question

我可以运行一个命令来查看端口是否打开：

portqry -n servername -e 80

我想针对服务器列表运行它：

1. DEV1 80
2. DEV2 80
3. 付款80
4. TEST1 80
5. TEST2 80
6. PROD 80

我想使用单个Windows批处理脚本测试它们，并查看哪些端口打开以及哪些端口已关闭。 （而且我不希望它在第一个封闭的端口上掉下来）。

我的问题是：是否有Windows批处理脚本来查看服务器/端口序列是否已打开？

附加：我知道还有其他问题询问如何检查端口是否打开。它们都不是以可靠的方式为一系列端口编写脚本。

Answer 1

干得好。向前付款。 :)要直接回答你的问题，只需使用for循环遍历你的服务器并在每个服务器上执行portqry。编辑：您找到的PowerShell代码段对于摆脱PortQry依赖项非常有用。

@echo off
setlocal

set "servers=dev1 dev2 dev3 test1 test2 test2:8080 prod prod:443"

for %%I in (%servers%) do (
    for /f "tokens=1,2 delims=:" %%a in ("%%I") do (
        set "port=%%~b"
        if not defined port set "port=80"
        setlocal enabledelayedexpansion
        call :handshake "%%~a" "!port!" && (
            echo %%a port !port!: OK
        ) || (
            echo %%a port !port!: Error
        )
        endlocal
    )
)

goto :EOF

:handshake <server> <port>
powershell "$t=new-object Net.Sockets.TcpClient;$c=$t.BeginConnect('%~1',%~2,{},{});if($c.AsyncWaitHandle.WaitOne(1000)){$t.EndConnect($c);exit 0};exit 1"
exit /b %ERRORLEVEL%

这是使用PortQry 2.0的原始解决方案：

@echo off
setlocal

set "servers=dev1 dev2 dev3 test1 test2 test2:8080 prod prod:443"

for %%I in (%servers%) do (
    for /f "tokens=1,2 delims=:" %%a in ("%%I") do (
        set "port=%%~b"
        if not defined port set "port=80"
        setlocal enabledelayedexpansion
        portqry -n "%%~a" -e "!port!" >NUL 2>NUL && (
            echo %%a port !port!: OK
        ) || (
            echo %%a port !port!: Error
        )
        endlocal
    )
)

---

如果您正在测试的只是Web服务，那么以不同的方式进行此操作可能更有意义。您可以使用Microsoft.XMLHTTP COM对象来摆脱portqry依赖;因此获得的响应将与HTTP服务更相关。 （例如，如果您在端口8080上运行VNC服务器而您希望Web服务正在侦听，那么portqry可能会在您需要它返回失败时返回成功。）

无论如何，将其保存为.bat脚本和盐味。

@if (@CodeSection == @Batch) @then

@echo off
setlocal

set "servers=dev1 dev2 dev3 test1 test2 test2:8080 prod prod:443"

for %%I in (%servers%) do (
    for /f "tokens=1,2 delims=:" %%a in ("%%I") do (
        set "port=%%~b"
        if not defined port set "port=80"
        setlocal enabledelayedexpansion
        cscript /nologo /e:JScript "%~f0" "%%~a" "!port!" && (
            echo %%a port !port!: OK
        ) || (
            echo %%a port !port!: Error
        )
        endlocal
    )
)

goto :EOF

@end // end batch / begin JScript chimera

var server = WSH.Arguments(0),
    port = WSH.Arguments(1),
    protocol = port == 443 ? 'https' : 'http',
    URL = protocol + '://' + server + ':' + port + '/',
    XHR = WSH.CreateObject('Microsoft.XMLHTTP');

XHR.open('GET', URL);
XHR.setRequestHeader('User-Agent','XMLHTTP/1.0');
XHR.send('');
while (XHR.readyState != 4) WSH.Sleep(25);
WSH.Quit(XHR.status - 200);

Answer 2

这就是我最终用上面的VBScript替换 - 一个名为porttest.ps1的文件，它与powershell -f porttest.ps1一起运行

param(
    [string] $remoteHost = "arbitrary-remote-hostname",
    [int] $port = 23
     )

# Open the socket, and connect to the computer on the specified port
write-host "Connecting to $remoteHost on port $port"
$tcpobject = new-Object system.Net.Sockets.TcpClient 
$connect = $tcpobject.BeginConnect($remoteHost,$port,$null,$null) 
#Configure a timeout before quitting - time in milliseconds 
$wait = $connect.AsyncWaitHandle.WaitOne(1000,$false) 
If (-Not $Wait) {
    'Timeout'
    exit 1
} Else {
    $error.clear()
    $tcpobject.EndConnect($connect) | out-Null 
        If ($Error[0]) {
            Write-warning ("{0}" -f $error[0].Exception.Message)
            exit 1
        } Else {
            'Port open!'
            exit 0
        }
    }

Answer 3

与上面不同，这根本不需要PowerShell，如果安装了telnet客户端，它应该适用于所有版本的windows（dism /online /Enable-Feature /FeatureName:TelnetClient）

如果有人可以解决如何停止telnet命令输出任何东西请添加注释，因为如果我添加重定向它拒绝运行。我相信telnet需要一个stdout，不能重定向。

为此，只需将两个127.0.0.1 IP地址更改为您要扫描的主机。

break>Results.txt & (for /l %a in (1,1,49152) do @taskkill /im telnet.exe /f >NUL 2>&1 & @start /b telnet.exe 127.0.0.1 %a & for /f %i in ('netstat -n ^| findstr /r /c:"TCP[ ][ ]*127.0.0.1:%a[ ][ ]*.*ESTABLISHED" ^| findstr /n ".*" ^| findstr "^1:"') do @echo "TCP Port Open: %a" >> Results.txt) & taskkill /im telnet.exe /f >NUL 2>&1

完成后，您可以输入结果

type Results.txt