如何更改vala中Gtk.Label的字体大小？

Question

我是 Vala/Gtk 新手，我正在尝试更改 Gtk.Label 的字体大小，但我找不到好的方法。

我发现我可以像这样使用标记：

    var welcome_message = new Gtk.Label ("<span size='17000'>Hello</span>");
    welcome_message.set_use_markup (true);

但这似乎有点hackish。 正确的做法是什么？

Answer 1

感谢 lethalman 和 nemequ。

我认为这可能会对某人有所帮助，所以这里有一个关于如何将 css 与 Vala 一起使用的小示例。

using Gtk;

public class StyleApp1 : Gtk.Window
{
    public StyleApp1() 
    {

        this.title = "Style app example";
        this.set_border_width (10);
        this.set_position (Gtk.WindowPosition.CENTER);

        this.set_default_size (350, 200);
        this.destroy.connect (Gtk.main_quit);

        var screen = this.get_screen ();
        var css_provider = new Gtk.CssProvider();

        string path = "styleapp1.css";

        // test if the css file exist
        if (FileUtils.test (path, FileTest.EXISTS))
        {
            try {
                css_provider.load_from_path(path);
                Gtk.StyleContext.add_provider_for_screen(screen, css_provider, Gtk.STYLE_PROVIDER_PRIORITY_USER);
            } catch (Error e) {
                error ("Cannot load CSS stylesheet: %s", e.message);
            }
        }

        var box = new Gtk.Box (Gtk.Orientation.VERTICAL, 10);
        this.add (box);

        var label = new Gtk.Label ("Thank you");
        box.add (label);

        var label2 = new Gtk.Label ("Stackoverflow");
        label2.get_style_context().add_class("my_class");
        box.add (label2);
    }
}
    
static int main(string[] args) {
    Gtk.init(ref args);
    
    StyleApp1 win = new StyleApp1();
    win.show_all();
    
    Gtk.main();
    return 0;
}

和 styleapp1.css 文件：

GtkWindow {
    font-size: 17px;
}

.my_class {
    color: pink;
}

注意：如果您使用 add_provider 而不是 add_provider_for_screen。您必须对要自定义的每个小部件使用 add_provider。

Answer 2

你可以尝试使用css，我认为最近这是首选方式。给你的标签一个类，然后加载一个CSS。如果您要更改标签的字体大小，我敢打赌您还会自定义其他内容，因此 CSS 可能对您有用。