如何在动态查询中使用表值参数

Question

我正在使用表值参数来使用以下代码构建动态查询

AlTER PROCEDURE [dbo].[ABC]  
     @tblName Varchar(1000), 
     @Details ABC_TYPE Readonly


AS 

   BEGIN

   Declare @PK as nvarchar(1000)
   Declare @SyncFlag as nvarchar(1) ='S'
   Declare @SelectCommand as nvarchar(1200)
   Declare @tblName2 as nvarchar(1000) ='@Details_N'    


  Set @PK = 'PK'


  Declare @Details_N as table (Pk int)
  Insert into @Details_N(Pk) 
  select PK from @Details

  set @SelectCommand =   'Update A ' + ' set A.Sync_Flag ='''+ @SyncFlag + ''' From '+ @tblName + ' A, '  + @tblName2 + ' B ' +
  ' where A.' + @PK +'='+  'B.PK' 

  EXEC sp_executesql @SelectCommand;

这给了我错误

必须声明表变量“@Details_N”

找不到我做错的地方

Answer 1

在动态查询内部，不能使用外部声明的表变量。请改用临时表。而且你把它弄得太复杂了，这是一个更干净的版本

DECLARE @SyncFlag AS NVARCHAR(1) ='S'
DECLARE @SelectCommand AS NVARCHAR(1200)

CREATE TABLE #Details_N(Pk INT)

INSERT INTO #Details_N(Pk)
SELECT PK
FROM   @Details

SET @SelectCommand = 'Update A ' + ' set A.Sync_Flag = @SyncFlag 
                        From '+ Quotename(@tblName) + ' A 
                        inner join #Details_N B '+ 'on A.PK =' + 'B.PK'

EXEC Sp_executesql
  @SelectCommand,
  N'@SyncFlag NVARCHAR(1)',
  @SyncFlag 

开始使用

INNER JOIN

语法，旧式逗号分隔连接已弃用

Answer 2

表变量的范围适用于特定批次（相同上下文），而临时表适用于 SPID。 EXEC 命令在不同的上下文中运行。使用临时表代替：

Declare @tblName2 as nvarchar(1000) ='#Details_N'  

CREATE TABLE  #Details_N (Pk int)
Insert into #Details_N(Pk) 
select PK from @Details