如何重新计算emacs组织模式中的列总数？

Question

可以说我们有以下结构：

|Element    |Price          |  
|first      |1              |  
|second     |2              |  
|Total      |:=vsum(@2..@-1)|  -> this will render: 3
#+TBLFM: @4$2=vsum(@2..@-1)  

现在让我们说插入一个新行：

|Element    |Price          |  
|first      |1              |  
|inserted   |10             |  
|second     |2              |  
|Total      |:=vsum(@2..@-1)|  -> this will still render 3, but it should render 13
#+TBLFM: @5$2=vsum(@2..@-1)  

那么当用新值插入新行时，如何自动更改总和？

Answer 1

Org-mode has limited ability to automatically recalculate tables：第一列可以用来添加一个特殊字符（#），它可以做你想要的，但只有当你想要重新计算的行中输入TAB，S-TAB或RET时（请注意，这也会添加此行）对缓冲区的全局重新计算也可能有用）。

这里的问题是org-mode不知道何时应该重新计算表，除非你告诉它（例如使用命令C-c *（org-ctrl-c-star））。一种选择是重新绑定org-mode中的一些或所有移动键绑定，以查看游标是否已启动并已移出表条目，如果是，则重新计算整个表，但我建议不要这样做。

在我看来，更好更容易的解决方案是在插入新行时让org-mode自动更新表（但不一定每次条目更改时）。这是一个Emacs Lisp函数（my-org-table-insert-row-and-recalculate-table），它通过提示用户输入每一列，然后重新计算表的所有公式，在当前函数之上创建一个新行。关于此功能的一些注意事项：

• 此函数需要在公式适用的第一行或下方运行，并且在公式适用的最后一行之上。如果不是，公式可能不会按预期更新（例如，使用的底行可能会超出公式范围）。这基于org-mode如何更新插入行的公式。
• 如果任何公式无效，更新过程可能无法完成（例如，公式#+TBLFM: $2=vsum(@2..@-1)将不适用于任何插入，因为org-mode尝试将其应用于参考@-1无效的第1列第2列）。
• 如果手动更新表条目，则仍需要手动调用表公式的重新计算过程。

(require 'subr-x)

(defun remove-empty-strings-list (list)
  (if (null list)
      '()
    (let ((rest (remove-empty-strings-list (cdr list))))
      (if (string= (car list) "")
          rest
        (cons (car list) rest)))))

(defun my-org-table--get-row-as-list ()
  (unless (org-at-table-p) (user-error "Not at a table"))
  (let ((line (buffer-substring-no-properties (line-beginning-position) (line-end-position))))
    (mapcar 'string-trim (remove-empty-strings-list (split-string line "|")))))

(defun my-org-table--get-top-row-as-list ()
  (save-excursion
    (org-table-goto-line 1)
    (my-org-table--get-row-as-list)))

(defun my-org-table--insert-string-row-and-recalculate-table (string)
  (org-table-with-shrunk-columns
   (beginning-of-line 1)
   (insert-before-markers string "\n")
   (org-table-align)
   (org-table-fix-formulas "@" nil (1- (org-table-current-dline)) 1)
   (org-table-iterate)))

(defun my-org-table--prompt-row ()
  (unless (org-at-table-p) (user-error "Not at a table"))
  (let ((top-row-list (my-org-table--get-top-row-as-list))
        (new-str "|")
        (cur-col 1))
    (dolist (top-item top-row-list)
      (let ((new-entry
             (read-string (concat "Enter entry (column #"
                                  (number-to-string cur-col)
                                  " - first entry: "
                                  top-item
                                  "): "))))
        (setq new-str (concat new-str new-entry "|")) ;; test placement
        (setq cur-col (+ 1 cur-col))))
    new-str))


(defun my-org-table-insert-row-and-recalculate-table ()
  "Interactively inserts row above point and then recalculates table"
  (interactive)
  (unless (org-at-table-p) (user-error "Not at a table"))
    (my-org-table--insert-string-row-and-recalculate-table (my-org-table--prompt-row)))

示例用法（'!!'表示缓冲区中的点，'>>'是迷你缓冲区提示符）：

| Element | Price |
| first   |     1 |
| second  |     2 |!!
| Total   |     3 |
#+TBLFM: @4$2=vsum(@2..@-1)

运行M-x my-org-table-insert-row-and-recalculate-table。

>> Enter entry (column #1 - first entry: Element): 
   inserted
>> Enter entry (column #2 - first entry: Price):
   100

输出：

| Element  | Price |
| first    |     1 |
| inserted |   100 |
| second   |     2 |
| Total    |   103 |
#+TBLFM: @5$2=vsum(@2..@-1)