动态创建的TPopup菜单不会在Delphi XE4中调用其项目的OnClick事件处理程序

Question

我想测试一些东西并创建一个简单的动态弹出菜单示例。我必须意识到弹出菜单正常显示，但它不会调用onClick事件处理程序。我试图重命名一切以避免名称冲突，使事件处理程序虚拟，公开，但它没有解决问题。我重新启动了IDE（我认为这段代码应该可以正常工作），但它是一样的。编译器选项是新项目的默认值。静态创建（放在表单上）popupmenu工作正常，只有动态创建的一个休息。我应该在动态菜单的哪个属性中填写一些值？有人解释原因，拜托！

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Menus;

type
  TForm1 = class(TForm)
    Button1: TButton;
    staticPopupMenu: TPopupMenu;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
    procedure addMenuItem( popupmenu_ : TPopupMenu; caption_ : string; tag_ : integer; onClick_ : TNotifyEvent );
    procedure onmenuitemclick1( sender_ : TObject );
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.addMenuItem( popupmenu_ : TPopupMenu; caption_ : string; tag_ : integer; onClick_ : TNotifyEvent );
var
  menuitem1 : tmenuitem;
begin
  menuitem1 := tmenuitem.create( popupmenu_ );
  menuitem1.caption := caption_;
  menuitem1.Tag := tag_;
  menuitem1.onclick := onclick_;
  popupmenu_.items.add( menuitem1 );
end;

procedure TForm1.onmenuitemclick1( sender_ : TObject );
var
  id : integer;
begin
  id := tmenuitem( sender_ ).Tag;
  showmessage( 'menuitem.onclick called! (' + intToStr( id ) + ')' );
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  dynamicPopupMenu : tpopupmenu;
begin
  dynamicPopupMenu := tpopupmenu.create( self );
  try
    addMenuItem( dynamicPopupMenu, 'aaa', 1, onmenuitemclick1 );
    addMenuItem( dynamicPopupMenu, 'bbb', 2, onmenuitemclick1 );
    dynamicPopupMenu.popup( 500, 500 );
  finally
    dynamicPopupMenu.Free;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  staticPopupMenu.items.Clear;
  addMenuItem( staticPopupMenu, 'aaa', 1, onmenuitemclick1 );
  addMenuItem( staticPopupMenu, 'bbb', 2, onmenuitemclick1 );
  staticPopupMenu.popup( 500, 500 );
end;

end.

dfm：

object Form1: TForm1
  Left = 339
  Top = 270
  Caption = 'Form1'
  ClientHeight = 601
  ClientWidth = 854
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  PixelsPerInch = 96
  TextHeight = 13
  object Button1: TButton
    Left = 96
    Top = 128
    Width = 75
    Height = 25
    Caption = 'Button1'
    TabOrder = 0
    OnClick = Button1Click
  end
  object Button2: TButton
    Left = 177
    Top = 128
    Width = 75
    Height = 25
    Caption = 'Button2'
    TabOrder = 1
    OnClick = Button2Click
  end
  object staticPopupMenu: TPopupMenu
    Left = 280
    Top = 128
  end
end

Answer 1

由于你使用当前的dynamicPopupMenu实例创建TForm1作为Owner，我不确定你需要垃圾收集器的所有装备，因为TForm1实例无论如何都会在它本身被破坏时将其破坏。

试试这个：

1. 在Classes.Pas中的TComponent.Destroy上设置一个断点，在Tag上设置一个监视器。
2. 如下所示更改您的Button1Click，禁用您的垃圾收集器，编译，运行和观察。

{码}

procedure TForm1.Button1Click(Sender: TObject);
var
  dynamicPopupMenu : tpopupmenu;
  AForm : TForm;
begin
  AForm := TForm.Create(Nil);
  dynamicPopupMenu := tpopupmenu.create(AForm);
  try
    dynamicPOpUpMenu.Tag := 666;
    addMenuItem( dynamicPopupMenu, 'aaa', 1, onmenuitemclick1 );
    addMenuItem( dynamicPopupMenu, 'bbb', 2, onmenuitemclick1 );
    dynamicPopupMenu.popup( 600, 600 );
  finally
    AForm.Release;
  end;
end;

Answer 2

这是我对这个问题的看法。用户定义的消息应该很好，只需很少的开销。所以...

定义Windows消息：

const
  WM_FREE_MY_DYNAMENU = WM_USER + 0;

将dynamicPopupMenu变量移动到表单并为消息定义处理程序：

TForm12 = class(TForm)
...
protected
  dynamicPopupMenu: TPopupMenu;
  procedure FreeMyDynaMenu(var Message: TMessage); message WM_FREE_MY_DYNAMENU;

实施它：

procedure TForm12.FreeMyDynaMenu(var Message: TMessage);
begin
  dynamicPopupMenu.Free;
end;

最后在Button1Click中替换对Free的调用并发布消息：

finally
//  dynamicPopupMenu.Free;
  PostMessage(self.Handle, WM_FREE_MY_DYNAMENU, 0, 0);

您还应该在创建菜单时不将表单指定为所有者：

dynamicPopupMenu := tpopupmenu.create( nil ); // self replaced with nil

而上述更简单的替代方案（尽管不是我喜欢的）将是使用TTimer来延迟调用Free。