使用批处理文件SHIFT命令[重复]

Question

我尝试在屏幕上显示最多 9 个参数，然后在接下来的每一行中少显示一个参数，直到没有剩余。

我试过这个：

@echo off
echo %*
shift
echo %*
shift
echo %*

实际结果：

   a b c d e f
   a b c d e f

预期结果：

A B C D E F
B C D E F
C D E F
D E F
E F
F

Answer 1

如果你想获取

SHIFT

、

%1

等的值，

%2

是值得的。它不影响

%*

。 该脚本为您提供了您期望的输出。

@echo off
setlocal enabledelayedexpansion

set args=0
for %%I in (%*) do set /a "args+=1"
for /l %%I in (1,1,%args%) do (
    set /a idx=0
    for %%a in (%*) do (
        set /a "idx+=1"
        if !idx! geq %%I set /p "=%%a "<NUL
    )
    echo;
)

输出：

C:\Users\me\Desktop>test a b c d e f
a b c d e f
b c d e f
c d e f
d e f
e f
f

Answer 2

Shift 不会改变实际顺序，只是改变参数的索引/指针。

试试这个：

@echo off
echo %1
shift 
echo %1
shift
echo %1
echo %*

你会得到这个：

a
b
c
a b c d

Answer 3

“Shift 对 %* 批处理参数没有影响”

来源：http://www.microsoft.com/resources/documentation/windows/xp/all/proddocs/en-us/percent.mspx?mfr=true

我建议将你的代码更改为循环或其他东西

Answer 4

%*

始终打印命令行中的所有参数（

%0

除外）。它不支持 SHIFT 命令。

您需要按位置显式回显所有参数：

%1 %2 %3...

@echo off
:loop
if "%~1" neq "" (
  echo %1 %2 %3 %4 %5 %6 %7 %8 %9
  shift
  goto :loop
)