如何让CMake基于GCC版本传递std = c ++ 14 / c ++ 1y或c ++ 17 / c ++ 1z？

Question

GCC 4.x不接受用于C ++ 14代码的--std=c++14开关 - 它需要--std=c++1y。以后的版本采取--std=c++1z，但（可能）不是--std=c++17尚未设置（2016年写这个）。也许C ++ 11也存在类似的问题。

CMake是否有一些设施（可能作为模块）根据GCC版本传递正确的开关？

Answer 1

当想要指定特定的C ++版本时，使用CMake 3.1及更高版本执行此操作的推荐方法是使用CXX_STANDARD，CXX_STANDARD_REQUIRED和CXX_EXTENSIONS目标属性或其变量等效项来指定目标默认值。完整的细节可以找到here，但简短的版本是这样的：

cmake_minimum_required(VERSION 3.1)
project(Example)

set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
# ... Define targets, etc. as usual

然后，CMake应根据编译器支持的内容为所请求的C ++标准选择适当的编译器标志，否则如果它不支持所请求的标准则输出错误。

还应注意，CMake可以将目标升级为使用比其CXX_STANDARD目标属性指定的语言更晚的语言标准。使用compile feature requirements（如@FlorianWolters答案中所述）可以提高语言标准要求。事实上，CMake总是会选择CXX_STANDARD目标属性或目标上设置的编译功能要求所指定的更强大的语言要求。另请注意，3.10.1中的CMake文档并未准确反映CXX_EXTENSIONS与编译功能交互的方式，因为CXX_EXTENSIONS仅在为大多数常见编译器指定CXX_STANDARD时才生效（因为它们与一个编译器标志一起指定）。

Answer 2

现代CMake代码应使用target_compile_features命令来请求特定的C ++标准。这可以仅指定为构建要求（PRIVATE），仅限使用要求（INTERFACE）或构建和使用要求（PUBLIC）。

例：

cmake_minimum_required(VERSION 3.9.4)

project(cpp-snippets)
add_executable(cpp-snippets "main.cpp")
target_compile_features(cpp-snippets PRIVATE cxx_std_17)

有关cmake-compile-features的官方CMake文档，请参阅“需要语言标准”一节以了解更多信息。

Answer 3

检查编译器是否支持标志？也许是这样的

include(CheckCXXCompilerFlag)

# Check for standard to use
check_cxx_compiler_flag(-std=c++17 HAVE_FLAG_STD_CXX17)
if(HAVE_FLAG_STD_CXX17)
    # Have -std=c++17, use it
else()
    check_cxx_compiler_flag(-std=c++1z HAVE_FLAG_STD_CXX1Z)
    if(HAVE_FLAG_STD_CXX1Z)
        # Have -std=c++1z, use it
    else()
        # And so on and on...
    endif()
endif()