等待 Internet Explorer 中的 JavaScript 执行

Question

我正在尝试在 Excel VBA 中进行一些网页抓取。这是我遇到问题的代码部分：

IE.Navigate URL
Do
  DoEvents
Loop While IE.ReadyState <> 4 Or IE.Busy = True
Set doc = IE.document

运行后，这个

doc

包含的HTML中仍然有未执行的JavasScript。 这是尚未执行的脚本的签名：

<SCRIPT type=text/javascript>
        goosSearchPage.Initialize(...)...;
</SCRIPT>

我可以通过执行

Application.Wait(Now  + TimeValue(x))

来等待执行，但这确实不能令人满意，因为脚本执行所需的时间根据输入的不同而变化很大。

有没有办法等待脚本完成评估，或者直接在

doc

对象中评估脚本？

Answer 1

我发现代码确实等待页面完成。根据此处的注释，它需要 Microsoft Internet Controls 作为代码中的参考。

此处复制代码，以防链接失效：

'Following code goes into a sheet or thisworkbook class object module
Option Explicit

'Requires Microsoft Internet Controls Reference Library
Dim WithEvents ie As InternetExplorer
Sub start_here()
  Set ie = New InternetExplorer
  'Here I wanted to show the progress, so setting ie visible
  ie.Visible = True
  'First URL to go, next actions will be executed in
  'Webbrowser event sub procedure - DocumentComplete
  ie.Navigate "www.google.com"
End Sub
Private Sub ie_DocumentComplete(ByVal pDisp As Object, URL As Variant)
  'pDisp is returned explorer object in this event
  'pDisp.Document is HTMLDocument control that you can use
  'Following is a choice to follow,
  'since there is no do-loop, we have to know where we are by using some reference
  'for example I do check the URL and do the actions according to visited URL

  'In this sample, we use google entry page, set search terms, click on search button
  'and navigate to first found URL
  'First condition; after search is made
  'Second condition; search just begins
  If InStr(1, URL, "www.google.com/search?") > 0 Then
    'Open the first returned page
    ie.Navigate pDisp.Document.getelementsbytagname("ol")(0).Children(0).getelementsbytagname("a")(0).href
  ElseIf InStr(1, URL, "www.google.com") > 0 Then
    pDisp.Document.getelementsbyname("q")(0).Value = "VB WebBrowser DocumentComplete Event"
    pDisp.Document.getelementsbyname("btnG")(0).Click
  End If
End Sub

Answer 2

您实际上可以使用 ie 窗口评估 javascript 函数。但是你必须设置一个回调，因为该函数将被异步评估。

Answer 3

这篇文章已经很老了，但既然我已经发现了如何做到这一点，我也会回答这个问题作为对自己的回复。

只需指向您期望在 jQuery 脚本运行后出现的内容，使用通过 IE 自动化运行的 JavaScript 触发所需的事件，然后执行循环以等待所需的内容出现。

'This will trigger the jQuery event.
Doc.parentWindow.execScript "$('#optionbox').trigger('change')"

'This is the code that will make you wait. It's surprisingly efficient
Do While InStrB(Doc.getElementById("optionbox").innerHTML, "<desired html tag>") = 0
    DoEvents
Loop