在ANTLR中，是否有一个快捷符号表示某些规则集的所有排列的交替？

Question

在ANTLR中，我想定义一个这样的规则：

规则：（a b c | a c b | b a c | b c a | c a b | c b a）;

但在我的情况下，我有10个规则而不是3个，我想要置换，因此它变得非常不切实际。有没有办法在ANTLR中表达这一点而不必写出所有的排列？

Answer 1

我会匹配任何a，b或c一次或多次：

rule
 : ( a | b | c )+
 ;

然后，在解析之后，遍历解析树并检查a，b和c是否都匹配了一次。

但是，在语法本身可以通过在需要的地方使用谓词来实现。

演示：

grammar Permutation;

parse
  :  permutation[5] {System.out.println("parsed: " + $permutation.text);} EOF
  ;

permutation[final int n]
@init{
  java.util.Set set = new java.util.HashSet();
  int counter = n;
}
  :  (
       {counter > 0}?=> token   // keep matching a `token` as long as `counter > 0`
       {                        //
         set.add($token.text);  // add the contents of `token` to `set`
         counter--;             // decrease `counter`
       }                        //
     )+ 
     {set.size() == n}?         // if `set.size() != n`, an exception is thrown
  ;

token
  :  A
  |  B
  |  C
  |  D
  |  E
  ;

A : 'A';
B : 'B';
C : 'C';
D : 'D';
E : 'E';

Space : ' ' {skip();};

上面的演示语法使用2种不同类型的谓词：1）门控语义谓词i以确保permutation规则不超过参数final int n标记，以及2）验证语义谓词i以确保set完全保持final int n元素，以确保它是5个令牌的正确排列。

有关语义谓词的更多信息，请访问：What is a 'semantic predicate' in ANTLR?

您可以使用以下类测试语法：

import org.antlr.runtime.*;

public class Main {
  public static void main(String[] args) throws Exception {
    PermutationLexer lexer = new PermutationLexer(new ANTLRStringStream(args[0]));
    PermutationParser parser = new PermutationParser(new CommonTokenStream(lexer));
    parser.parse();
  }
}

java -cp antlr-3.3.jar org.antlr.Tool Permutation.g 
javac -cp antlr-3.3.jar *.java

java -cp .:antlr-3.3.jar Main "A B C D E"
parsed: ABCDE

java -cp .:antlr-3.3.jar Main "B D C E A"
parsed: BDCEA

java -cp .:antlr-3.3.jar Main "A B C D B"
line 1:9 rule permutation failed predicate: {set.size() == n}?
parsed: null