Fortran：分段错误

Question

我知道我曾经提出过类似的话题，但是那是不同的。这次，添加打印语句不会更改我是否遇到段错误。

    call omp_set_num_threads(omp_get_max_threads())
    !$omp parallel do  &
    !$omp default(firstprivate) &
    !$omp private(present_surface) &
    !$omp lastprivate(fermi)
    do m = 1, fourth 
        do n = 1, third
            do j = 1, second
                do i = 1, first
                    !current angle is phi[i,j,ii,jj]
                    !we have to find the current fermi surface
                    present_surface = 0.
                    do a = 1, fourth    
                        if (angle(i,j,n,m) == angle_array(a)) then
                            present_surface = surface(a)
                        end if
                    end do 
                    if (radius(i,j,n,m) >= present_surface) then 
                        fermi(i,j,n,m) = 0.
                    else 
                        fermi(i,j,n,m) = 1.
                    end if          
                end do      
            end do      
        end do
    end do  
    !$omp end parallel do

我不确定lastprivate（fermi）语句，但是现在不重要。共享具有相同的行为。

因此，我运行此脚本时增加了“第一，第二，第三，第四”。典型输出：

[10] Time elapsed is 0.001 [s].
[15] Time elapsed is 0.002 [s].
[20] Time elapsed is 0.005 [s].
./compile: line 2:  4310 Segmentation fault      python fortran_test.py

嗯，如何进行。我看着gdb python；运行fortran_test.py，发现：

(gdb) run fortran_test.py 
Starting program: /usr/bin/python fortran_test.py
[Thread debugging using libthread_db enabled]
[New Thread 0x7fffed9b0700 (LWP 4251)]
[New Thread 0x7fffe8ba5700 (LWP 4252)]
[New Thread 0x7fffe83a4700 (LWP 4253)]
[New Thread 0x7fffe7ba3700 (LWP 4254)]
[10] Time elapsed is 0.008 [s].
[15] Time elapsed is 0.004 [s].
[20] Time elapsed is 0.005 [s].

Program received signal SIGSEGV, Segmentation fault.
[Switching to Thread 0x7fffe7ba3700 (LWP 4254)]
0x00007fffe8dc0bb7 in __populate_MOD_fermi_integrand._omp_fn.0 () at     populate.f90:31
31                              do n = 1, third

[如果我在内部循环中更改某些内容，例如，删除j，i循环并将其置于常量中，那么我只会在另一行获得段错误。

I think这与内存有关，因为它随着N的增加而触发。但是，我尝试过的东西（导出GOMP_STACKSIZE，OMP_STACKSIZE，ulimit）尚未解决，我发现使用它们没有区别。 （暂时将其删除）。

最后，要编译的命令（在f2py中）：

 f2py --fcompiler=gfortran --f90flags="-fopenmp -g" -lgomp -m -c populate populate.f90

如您所见，我很困惑。我希望你们中的一些人知道如何解决问题。

我的目标是使N = 100快速运行（因此使用openMP fortran函数），但这对于fortran代码而言应该无关紧要，对吧？

如果您想知道，那么4GB的内存和我的交换空间是3.1G（Linux Swap / Solaris）。

谢谢！

Answer 1

default(firstprivate) lastprivate(fermi)表示每个线程接收angle，radius和fermi的私有副本，每个副本的大小均为first x second x third x fourth。以我的经验，即使给出了将大数组自动转换为堆数组的选项，私有数组也总是分配在堆栈上。您的代码很可能由于堆栈空间不足而崩溃。

而不是将所有内容都私有，您应该真正了解数据依赖性并选择正确的数据共享类。永远不会写入angle，angle_array，surface和radius，因此它们都应为shared。 present_surface正在修改，应为private。 fermi被写入但不能在同一位置被多个线程写入，因此也应为shared。另外，请注意lastprivate不会获得预期的结果，因为它会提供在执行m循环的逻辑上最后一次迭代的线程中具有的相应变量的值。 first，second，third和fourth仅被视为常量，应为shared。循环变量当然是private，但是由编译器自动执行。

!$omp parallel do private(present_surface)
do m = 1, fourth 
    do n = 1, third
        do j = 1, second
            do i = 1, first
                !current angle is phi[i,j,ii,jj]
                !we have to find the current fermi surface
                present_surface = 0.
                do a = 1, fourth    
                    if (angle(i,j,n,m) == angle_array(a)) then
                        present_surface = surface(a)
                    end if
                end do 
                if (radius(i,j,n,m) >= present_surface) then 
                    fermi(i,j,n,m) = 0.
                else 
                    fermi(i,j,n,m) = 1.
                end if          
            end do      
        end do      
    end do
end do  
!$omp end parallel do

Answer 2

一个非常可能的原因是堆栈限制。首先运行ulimit -s以检查该进程的堆栈限制。您可以使用ulimit -s unlimited将其设置为无限。然后，如果仍然崩溃，请尝试通过将OMP_STACKSIZE环境变量设置为较大的值（例如100MB）来增加OPENMP的堆栈。

[Intel在https://software.intel.com/en-us/articles/determining-root-cause-of-sigsegv-or-sigbus-errors进行了讨论。它具有堆栈和堆内存的更多信息。