NSIS - 通过 CMD 命令监控变量的刷新率

Question

这就是我通过在 CMD 中键入以下命令来获取主显示器刷新率的方法：

wmic PATH Win32_videocontroller get currentrefreshrate

结果：

CurrentRefreshRate
144
75

第二行是我的主显示器的刷新率。我想把这个数字分配给一个名为

$refreshrate

的变量。如何实现这一目标？

Answer 1

你不必依赖外部工具，可以直接询问系统：

对于整个屏幕：

!include LogicLib.nsh
Section
!define /IfNDef VREFRESH 116
System::Call USER32::GetDC(p0)p.r0
System::Call GDI32::GetDeviceCaps(pr0,i${VREFRESH})i.r1
System::Call USER32::ReleaseDC(p0,pr0)
${If} $1 < 5
    StrCpy $1 "Invalid"
${EndIf}
DetailPrint "Refresh rate=$1"
SectionEnd

当前显示应用程序（线程）所在位置：

!include LogicLib.nsh
Section
!define /IfNDef ENUM_CURRENT_SETTINGS -1
!define /IfNDef DM_DISPLAYFREQUENCY 0x00400000

System::Call 'USER32::GetClientRect(p0,@r1)' ; Lazy allocation of a DEVMODE
System::Call '*$1(&i68,&i2 68)'
System::Call 'USER32::EnumDisplaySettingsW(p0, i${ENUM_CURRENT_SETTINGS}, pr1)i.r0'
System::Call '*$1(&i72,i.r2)'
${If} $0 <> 0
${AndIf} $2 & ${DM_DISPLAYFREQUENCY}
    System::Call '*$1(&i184,i.r3)'
    DetailPrint "Current display=$3"
${EndIf}
SectionEnd

主适配器：

!include LogicLib.nsh
Section
!define /IfNDef ENUM_CURRENT_SETTINGS -1
!define /IfNDef DM_DISPLAYFREQUENCY 0x00400000
!define /IfNDef DISPLAY_DEVICE_PRIMARY_DEVICE 4
System::Call 'USER32::GetClientRect(p0,@r1)' ; Lazy allocation of a DISPLAY_DEVICE 
StrCpy $4 0
loop:
System::Call '*$1(i840)'
System::Call 'USER32::EnumDisplayDevicesW(p0, ir4, pr1, i0)i.r0'
IntOp $4 $4 + 1
${If} $0 <> 0
    System::Call '*$1(i,&w32.r2,&w128,i.r3)'
    ${If} $3 & ${DISPLAY_DEVICE_PRIMARY_DEVICE}
        System::Call '*$1(&i68,&i2 68)' ; DEVMODE
        System::Call 'USER32::EnumDisplaySettingsW(wr2, i${ENUM_CURRENT_SETTINGS}, pr1)i.r0'
        System::Call '*$1(&i72,i.r2)'
        ${If} $0 <> 0
        ${AndIf} $2 & ${DM_DISPLAYFREQUENCY}
            System::Call '*$1(&i184,i.r3)'
            DetailPrint "Primary adapter=$3"
        ${EndIf}
    ${Else}
        Goto loop
    ${EndIf}
${EndIf}
SectionEnd

如果您真的想使用 WMI：

!include "StrFunc.nsh"  
${Using:StrFunc} StrRep 
!include LogicLib.nsh
Section
nsExec::ExecToStack '"wmic.exe" PATH Win32_videocontroller get  currentrefreshrate /all'
Pop $0
Pop $1
${StrRep} $1 $1 "currentrefreshrate" ""
loop:
    StrCpy $2 $1 1
    ${If} $2 == "$\r"
    ${OrIf} $2 == "$\n"
    ${OrIf} $2 == " "
        StrCpy $1 $1 "" 1
        Goto loop
    ${EndIf}
IntOp $2 $1 + 0 ; First number
${If} $0 = 0
    DetailPrint WMIC=$2
${EndIf}
SectionEnd

Answer 2

这可以使用以下批处理文件代码来完成：

@set "RefreshRate=" & for /F "tokens=2 delims==" %%I in ('%SystemRoot%\System32\wbem\wmic.exe PATH Win32_VideoController GET CurrentRefreshRate /VALUE 2^>nul') do @if not defined RefreshRate set "RefreshRate=%%I"

更容易阅读的是：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
for /F "tokens=2 delims==" %%I in ('%SystemRoot%\System32\wbem\wmic.exe PATH Win32_VideoController GET CurrentRefreshRate /VALUE 2^>nul') do set "RefreshRate=%%I" & goto HaveRate
echo Failed to determine the refresh rate of primary monitor.
goto EndBatch

:HaveRate
echo Refresh rate of primary monitor is: %RefreshRate%

:EndBatch
endlocal
pause

要了解所使用的命令及其工作原理，请打开命令提示符窗口，执行以下命令，并完整、仔细地阅读每个命令显示的帮助页面。

• echo /?

• endlocal /?

• for /?

• goto /?

• pause /?

• set /?

• setlocal /?

• wmic /?

• wmic path /?

• wmic path Win32_VideoController /?

• wmic path Win32_VideoController get /?

阅读有关 使用命令重定向运算符的 Microsoft 文档，了解

2>nul

的说明。重定向运算符

>

必须在

FOR

命令行上使用脱字符号 ^ 进行转义，以便在 Windows 命令解释器在执行命令 FOR（执行嵌入的

wmic

命令行）之前处理此命令行时将其解释为文字字符使用在后台启动的单独命令进程，并使用

%ComSpec% /c

和

'

中的命令行作为附加参数附加。

请注意，WMIC输出始终是使用 UTF-16 Little Endian 和字节顺序标记 (BOM) 进行 Unicode 编码，在处理此输出时必须考虑到这一点。

我对 NSIS 一无所知，因此不知道如何从 NSIS 脚本中运行 Windows 命令并将其输出分配给 NSIS 的变量。

可以使用以下命令行来运行

cmd.exe

，它以第一个（主）监视器的刷新率退出。

cmd.exe /E:ON /C "@for /F "tokens=2 delims==" %I in ('%SystemRoot%\System32\wbem\wmic.exe PATH Win32_VideoController GET CurrentRefreshRate /VALUE 2^>nul') do @exit /B %I"

如果命令行无法确定刷新率，则

cmd.exe

的退出代码为0。否则，

cmd.exe

返回的退出代码是第一个（主）监视器的刷新率值。