如何使用 Modelica.Media.Water 库查找饱和蒸汽密度？

Question

对于大气压（约 101420 Pa）下的液态水，我想使用 Modelica.Media.Water 库确定相应的饱和蒸汽密度（直接穿过 Pv 曲线）。

我一直在关注 Modelica.Media.Examples.TwoPhaseWater 示例并找出如何获取饱和液体的密度。 然而，我一直在试图弄清楚如何获得相应的蒸气态及其密度。

model Example_3


  parameter Modelica.Units.SI.Pressure p = 101420;
  replaceable package Medium = Modelica.Media.Water.StandardWater ;
  
  
  Medium.ThermodynamicState satLiquidState;
  Medium.ThermodynamicState satVaporState;

  Modelica.Units.SI.Temperature T_sat;
  
  Modelica.Units.SI.Density rho_f;
  Modelica.Units.SI.Density rho_g;

  Real nu_f(unit="kg/m3");
  Real nu_g(unit="kg/m3");
 
  Medium.SaturationProperties dew "Dew line Properties";
  
equation
  satVaporState = Medium.setDewState(dew);
  T_sat = Medium.saturationTemperature(p);
  satLiquidState = Medium.setState_pT(p,T_sat);
 
  rho_f = satLiquidState.d;
  nu_f = 1/rho_f;
  rho_g = satVaporState.d;
  nu_g = 1/rho_g;
end Example_3;

通过简单的查找，我可以看到属性值应该是
ν_g = 1.6941 m³/kg 或 ρ_g = 0.5903 kg/m³
ν_f = 0.001043 m³/kg 或 ρ_f = 958.7728 kg/m³

Answer 1

这是一个工作示例

model Example_4
  parameter Modelica.Units.SI.Pressure p = 101420;
  replaceable package Medium = Modelica.Media.Water.StandardWater;

  Modelica.Units.SI.Temperature T_sat;

  Modelica.Units.SI.Density rho_f;
  Modelica.Units.SI.Density rho_g;

  Modelica.Units.SI.SpecificVolume nu_f;
  Modelica.Units.SI.SpecificVolume nu_g;

  Medium.SaturationProperties dew "Dew line Properties";
equation 
  dew.psat = p;
  dew.Tsat = T_sat;

  T_sat = Medium.saturationTemperature(p);
  rho_f = Medium.bubbleDensity(dew);
  nu_f = 1/rho_f;
  rho_g = Medium.dewDensity(dew);
  nu_g = 1/rho_g;
end Example_4;