如何在BATCH文件中使用SWITCH解析命令行参数

Question

我们正在尝试创建一个 switch 语句来解析批处理文件中的命令行参数。

mybatch.bat -a 10 -b name -c India --zipcode 20

只有

-a

、

-b

、

-c

是解析参数（以

-

开头）。

我们的代码如下：

for %%x in (%*) do (
     switch(%%x) (
          case a:
                 SET first_number=%arg%
                 break
          case b:
                 SET name=%arg%
          case c:
                 for %%x in (%*) do (
                       SET place =%place% %arg%
                  )
          default:
                  echo wrong parameter
           )

Answer 1

下面的批处理文件解析以

-

开头的所有参数，并创建一系列以“option”开头的变量以及给定的所有选项的名称和值：

@echo off
setlocal EnableDelayedExpansion

set "option="
for %%a in (%*) do (
   if not defined option (
      set arg=%%a
      if "!arg:~0,1!" equ "-" set "option=!arg!"
   ) else (
      set "option!option!=%%a"
      set "option="
   )
)

SET option

例如：

>test -a 10 -b name -c India --zipcode 20
option--zipcode=20
option-a=10
option-b=name
option-c=India

这样，如果您想添加/更改/删除任何选项，则不需要对解析代码进行任何更改，只需使用您想要的选项的值即可。例如：

if defined option-x (
   echo Option -x given: "%option-x%"
) else (
   echo Option -x not given
)

Answer 2

通常，您会尝试使事情变得简单并为参数设定一个顺序。要以任何随机顺序处理参数，比仅仅知道 %1 = 数字、%2 = 名称和 %3 以后 = 位置要付出更多的努力。

也就是说，这是一个解决方案的尝试。我忽略了 place 部分中的 --params，只是将这些值连接在一起。

@echo off
setlocal

:loop
if x%1 equ x goto done
set param=%1
if %param:~0,1% equ - goto checkParam
:paramError
echo Parameter error: %1 

:next
shift /1
goto loop

:checkParam
if "%1" equ "-a" goto A
if "%1" equ "-b" goto B
if "%1" equ "-c" goto C
goto paramError

:A
    shift /1
    set first_number=%1
    goto next

:B
    shift /1
    set name=%1
    goto next

:C
    set place=
:GetPlaces
    shift /1
    set param=%1
    if not defined param goto donePlaces
    if %param:~0,2% equ -- (
        shift /1
        goto processPlace
    )
    if %param:~0,1% equ - goto donePlaces
:processPlace
echo.%place%
    if x%1 neq x (
        set place=%place% %1
        goto GetPlaces
    )
:donePlaces
    rem remove leading space
    if defined place set place=%place:~1%
    goto loop



:done

echo num=%first_number%     name=%name%     place=%place%

Answer 3

批处理中没有 switch 命令。您需要使用 if 语句来解决此问题：

@echo off
setlocal enableDelayedExpansion
for /l %%a in (1,2,6) do (
    set /a next=%%a+1

    set param=%%a

    call set _param=%%!param!
    call set _next=%%!next!

    rem echo -!next! -!_next! #!_param! #%%a 

    if "!_param!" equ "-a" (
        set first_number=!_next!
    )

    if "!_param!" equ "-b" (
        call set name=!_next!
    )

    if "!_param!" equ "-c" (
        set place=!_next!
    )

)

for %%a in (place first_number name) do (
    if not defined %%a set wrong_parameter=1
)

if defined wrong_parameter (
    echo wrong parameter
)

echo %place% %first_number% %name%

Answer 4

Aacini 的解决方案非常聪明，完全满足了要求，值得称赞！

我有一个扩展的要求：带有值的开关和不带值的开关的混合是任意顺序的参数。例如，对于递归处理，只需输入 -r，而不是 -r 后跟一个值。根据 Aacini 的解决方案，如果一个开关直接跟随另一个开关，则第二个开关将被用作第一个开关的值。

因此，我增强了 Aacini 的解决方案。在我的解决方案中，如果提供的开关 -x 没有值作为输入参数，则会创建一个变量 option-x，并将其设置为 1。

set "option="
for %%a in (%*) do (
    set arg=%%a
    if not defined option (
        if "!arg:~0,1!" equ "-" (
            set "option=!arg!"
            set "option!arg!=1"
        )
    ) else (
        if "!arg:~0,1!" neq "-" (
            set "option!option!=!arg!"
            set "option="
        ) else (
            set "option=!arg!"
        )
    )
)
set "option="

所以，例如

test -r -scale 100 

将定义两个变量：

option-r=1
option-scale=100