如何在 Vibe.d 中使用 HTTP 代码返回 JSON？

Question

我不仅想返回 JSON，还想返回 HTTP 响应代码。

我正在通过 URLRouter 注册 REST 接口：

router.registerRestInterface(new ClientServerAPI);

我的 REST 实现示例：

module clienserverapi.clientserver;

import api.clientserver;
import models.replies.client_versions;

/**
    Implementation of Client-Server API.
*/
class ClientServerAPI : IClientServerAPI {
@safe:
    ClientVersions getSupportedClientVersions() {
        bool[string] unstableFeatures;
        return ClientVersions(supportedVersions.dup, unstableFeatures);
    }
}

Answer 1

在 REST 接口生成器中，响应代码是自动处理的，并且由于您无法将 HTTPServerResponse/HTTPServerRequest 参数传递到 REST 方法中，因此您无法控制返回的状态。

但是，有一些内置状态需要处理：

• 根据内容返回200/204
• 400 参数不匹配的错误请求
• 404 未找到不匹配的路线
• 大多数异常都会返回 500 内部服务器错误
• （调试模式之外）发送未经授权的/错误的请求/禁止的请求

另请参阅：REST 接口文档

并且您可以使用 HTTPStatusException 控制任何状态代码，但是它会被视为错误，并会导致预定义的错误 json，其中将 statusMessage 作为异常消息集并返回您传递给它的 HTTP 状态代码。 （这可能是您想要的错误处理）

您还可以通过将 errorHandler 设置为 RestInterfaceSettings 中的 RestErrorHandler 委托来更改错误的外观。

或者，根据您想要执行的操作，您可以使用 WebInterface，它很像 REST 接口，但没有 REST 接口所具有的一些便利功能，而是可以完全访问请求/响应参数，并且基本上可以做任何像普通 http 路由一样的事情，并有一些 other 方便的功能，你可以使用。

理论上，如果你想用数据返回自定义成功代码，你可以滥用 errorHandler + HTTPStatusException 和有效的 HTTP 状态代码，但我不鼓励这样做，而是使用 Web 界面（如果这就是你想要的）。

但是，如果您只想使用自定义错误代码和自定义但一致的错误页面，那么我肯定会使用带有 errorHandler 的 REST 接口。

你现在可能看起来像这样：

import vibe.vibe;
import std.uni;

@safe:

void main() {
    auto server = new HTTPServerSettings;
    server.port = 3000;
    server.bindAddresses = ["::1", "127.0.0.1"];
    auto router = new URLRouter;

    RestInterfaceSettings settings = new RestInterfaceSettings();
    // this is how the error page will look on any thrown exception (like HTTPStatusException)
    settings.errorHandler = (HTTPServerRequest req, HTTPServerResponse res,
            RestErrorInformation error) @safe {
        res.writeJsonBody([
            // design this however you like
            "ok": Json(false),
            "error": serializeToJson([
                "status": Json(cast(int)error.statusCode),
                "message": Json(error.exception.msg),
                "parent": Json("/api/something")
            ])
        ]);
    };
    router.registerRestInterface(new Impl, settings);

    listenHTTP(server, router);
    runApplication();
}

interface RestAPI {
    string getGreeting(string name);
}

class Impl : RestAPI {
    string getGreeting(string name)
    {
        // throw an HTTP Bad Request error when name is empty
        if (name.length == 0)
            throw new HTTPStatusException(HTTPStatus.badRequest, "Name parameter cannot be empty!");
        // throw an HTTP Conflict error code when name is Bob
        if (sicmp(name, "bob") == 0)
            throw new HTTPStatusException(HTTPStatus.conflict, "Server cannot greet Bob!");
        return "Hello, " ~ name ~ "!";
    }
}

然后您的服务器将响应如下内容：

{
    "ok": false,
    "error": {
        "message": "Server cannot greet Bob!",
        "status": 409,
        "parent": "/api/something"
    }
}

Answer 2

您可以尝试 Hunt 框架，Rest api 的示例代码：

module app.controller.myapi;

import hunt.framework;

import app.message.UserMessage;

class MyapiController : Controller
{
    mixin MakeController;

    @Action
    JsonResponse test()
    {
        UserMessage user;
        user.id = 1;
        user.name = "MyName";
        user.email = "[email protected]";

        return new JsonResponse(user);
    }
}

您的回复结构：

module app.message.ResultMessage;

struct UserMessage
{
    int id;
    string name;
    string email;
}

响应结果为：

[ "id": 1, "name": "MyName", "email": "[email protected]" ]