Gnuplot：使用调色板时数据点的透明度

Question

使用调色板时是否可以绘制透明数据点？

我目前有以下代码：

set style fill transparent solid 0.2 noborder
set palette rgb 22,13,-22
plot 'mydata.dat' u 1:2:3 ps 0.3 palette

我的感觉是透明度被plot命令的参数覆盖。

Answer 1

使用调色板时是否可以绘制透明数据点？

如果您选择help palette，您将找不到（或我忽略了）关于调色板透明度的声明。看起来您可以用不同的方式为RGB设置调色板，但不能为ARGB设置调色板（A =透明度的alpha通道）。因此，我认为调色板不可能具有透明性（如果我错了，请纠正我）。解决方法是，必须通过手动设置颜色来设置透明度。您可以通过键入show palette rgbformulae在调色板后面找到公式。

以下示例创建了一个图，该图具有xrange[0:1]和yrange[0:1]中的随机点位置，随机点大小（从2到6）和随机透明度（从0x00到0xff）。颜色由x根据您的“手动调色板”确定。我希望您可以根据需要调整此示例。

代码：

### "manual" palette with transparency
reset session

# These are the rgb formulae behind palette 22,13,-22
set angle degrees
r(x) = 3*x-1 < 0 ? 0: (3*x-1 > 1) ? 1 : 3*x-1
g(x) = sin(180*x)
b(x) = 1-(3*x-1) < 0 ? 0: (1-(3*x-1) > 1) ? 1 : 1-(3*x-1)

set xrange [0:1]
set yrange[-0.1:1.1]

RandomSize(n) = rand(0)*4+2              # random size from 2 to 6
RandomTransp(n) = int(rand(0)*0xff)<<24  # random transparency from 0x00 to 0xff
myColor(x) = (int(r(x)*0xff)<<16) + (int(g(x)*0xff)<<8) + int(b(x)*0xff) + RandomTransp(0)

set samples 200
plot '+' u (x=rand(0)):(rand(0)):(RandomSize(0)):(myColor(x)) w p pt 7 ps var lc rgb var not

### end of code

结果：