Jenkins使用groovy脚本添加Git Behaviors

Question

我正在使用groovy脚本创建我的Jenkins实例，因为我正在自动化Jenkins创建过程。我创建这个脚本：

/* Adds a multibranch pipeline job to Jenkins */
import hudson.model.*
import hudson.util.PersistedList
import jenkins.*
import jenkins.branch.*
import jenkins.model.*
import jenkins.model.Jenkins
import jenkins.plugins.git.*
import com.cloudbees.hudson.plugins.folder.computed.PeriodicFolderTrigger
import org.jenkinsci.plugins.workflow.multibranch.*

// Create job
def env = System.getenv()
Jenkins jenkins = Jenkins.instance
String jobName = "Job"
String jobScript = "Jenkinsfile"
def job = jenkins.getItem(jobName)

// Create the folder if it doesn't exist
if (job == null) {
  job = jenkins.createProject(WorkflowMultiBranchProject.class, jobName)
}
job.getProjectFactory().setScriptPath(jobScript)

// Add git repo
String id = null
String remote = env.CODE_COMMIT_URL
String includes = "*"
String excludes = ""
boolean ignoreOnPushNotifications = false
GitSCMSource gitSCMSource = new GitSCMSource(id, remote, null, includes, excludes, ignoreOnPushNotifications)
BranchSource branchSource = new BranchSource(gitSCMSource)

// Remove and replace?
PersistedList sources = job.getSourcesList()
sources.clear()
sources.add(branchSource)
job.addTrigger(new PeriodicFolderTrigger("1m"))

并将其粘贴在$JENKINS_HOME/ref/init.groovy.d/。当我启动Jenkins时，已经创建了作业。除此之外，我需要在我的工作中添加一些Git行为，我想知道是否有办法使用groovy脚本添加Git行为？

我的Git创建后：

我想在初始化时添加的Git行为（发现标签，签出匹配的本地分支，自定义用户名/电子邮件地址）

谢谢！

Answer 1

我认为你想要的是通过特征来管理（我还没有尝试过这个）：

import jenkins.plugins.git.traits.*

def traits = []
// Add your traits...
traits.add(new TagDiscoveryTrait())
traits.add(new LocalBranchTrait())
gitSCMSource.setTraits(traits)