Inno Setup自定义页面，其中包含多个目标文件夹，其行为类似于普通文件夹选择页面

问题描述 投票：1回答：2

我有以下代码（取自Use two/multiple selected directories from custom page in Files section）：

[Code]
var
  DirPage: TInputDirWizardPage;

function GetDir(Param: String): String;
begin
  Result := DirPage.Values[StrToInt(Param)];
end;

procedure InitializeWizard;
var
  S1, S2: String; 
begin
  S1 := SetupMessage(msgSelectDirDesc);
  StringChangeEx(S1, '[name]', 'ProgramName', false);
  S2 := SetupMessage(msgSelectDirLabel3);
  StringChangeEx(S2, '[name]', 'ProgramName', false);

  { create a directory input page }
  DirPage := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), S1, S2, False, '');
  { add directory input page items }
  DirPage.Add('Path to Apache:');
  DirPage.Add('Path to PHP:');
  DirPage.Add('Path to Server Files:');
  { assign default directories for the items from the previously stored data; if }
  { there are no data stored from the previous installation, use default folders }
  { of your choice }
  DirPage.Values[0] := GetPreviousData('Directory1', 'C:\Apache');
  DirPage.Values[1] := GetPreviousData('Directory2', 'C:\PHP');
  DirPage.Values[2] := GetPreviousData('Directory3', 'C:\Apache\htdocs\Server Files');
end;

procedure RegisterPreviousData(PreviousDataKey: Integer);
begin
  { store chosen directories for the next run of the setup }
  SetPreviousData(PreviousDataKey, 'Directory1', DirPage.Values[0]);
  SetPreviousData(PreviousDataKey, 'Directory2', DirPage.Values[1]);
  SetPreviousData(PreviousDataKey, 'Directory3', DirPage.Values[2]);
end;

我想让它的行为与传统的文件夹选择页面相似，因此在选择文件夹时，Inno Setup应保留默认文件夹名称，除非用户手动覆盖。即：如果我选择文件夹"C:\Program Files\"，它应该保留原始文件夹，如"C:\Program Files\PHP"或"C:\Program Files\Apache"。这可能吗？

inno-setup pascalscript
2个回答
1
投票

要获取“选择目标位置”（由AppendDefaultDirName directive触发）上的“浏览”按钮的默认行为，对于自定义页面上的“浏览”按钮，请设置CreateInputDirPage的以下参数：

  • AAppendDir到True
  • ANewFolderName到“默认文件夹名称”

问题是，这会影响所有输入框/按钮。虽然您只想影响第一个输入框/按钮（或者您希望每个框/按钮有不同的ANewFolderName）。

要仅修改某些框的行为，您必须从头开始重新实现其功能。虽然浏览对话框功能未公开。只有BrowseForFolder function，略有不同。

var
  DirPage: TInputDirWizardPage;

procedure NormalBrowseClick(Sender: TObject);
var
  Directory: string;
begin
  Directory := DirPage.Values[TButton(Sender).Tag];
  if BrowseForFolder(SetupMessage(msgWizardSelectDir), Directory, False) then
  begin
    DirPage.Values[TButton(Sender).Tag] := Directory;
  end;
end;

procedure InitializeWizard();
begin
  DirPage := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), '', '', True, 'Apache');
  { add directory input page items }
  DirPage.Add('Path to Apache:');
  DirPage.Add('Path to PHP:');
  DirPage.Add('Path to Server Files:');

  DirPage.Buttons[1].Tag := 1;
  DirPage.Buttons[1].OnClick := @NormalBrowseClick;
  DirPage.Buttons[2].Tag := 2;
  DirPage.Buttons[2].OnClick := @NormalBrowseClick;
  { assign default directories for the items from the previously stored data; if }
  { there are no data stored from the previous installation, use default folders }
  { of your choice }
  DirPage.Values[0] := GetPreviousData('Directory1', 'C:\Apache');
  DirPage.Values[1] := GetPreviousData('Directory2', 'C:\PHP');
  DirPage.Values[2] := GetPreviousData('Directory3', 'C:\Apache\htdocs\Server Files');
end;

要使用相同的“浏览”对话框获得确切的行为，您可以破解它调用隐藏的“选择目标位置”页面或其他隐藏的TInputDirWizardPage的功能，其中包含AAppendDir的不同设置：

var
  DirPage: TInputDirWizardPage;
  HiddenPage: TInputDirWizardPage;

procedure AppendDirBrowseClick(Sender: TObject);
begin
  HiddenPage.Values[0] := DirPage.Values[0];
  HiddenPage.Buttons[0].OnClick(HiddenPage.Buttons[0]);
  DirPage.Values[0] := HiddenPage.Values[0];
end;

function SkipPage(Sender: TWizardPage): Boolean;
begin
  Result := True;
end;

procedure InitializeWizard();
begin
  DirPage := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), '', '', False, '');

  DirPage.Add('Path to Apache:');
  DirPage.Add('Path to PHP:');
  DirPage.Add('Path to Server Files:');

  { assign default directories for the items from the previously stored data; if }
  { there are no data stored from the previous installation, use default folders }
  { of your choice }
  DirPage.Values[0] := GetPreviousData('Directory1', 'C:\Apache');
  DirPage.Values[1] := GetPreviousData('Directory2', 'C:\PHP');
  DirPage.Values[2] := GetPreviousData('Directory3', 'C:\Apache\htdocs\Server Files');

  DirPage.Buttons[0].OnClick := @AppendDirBrowseClick;

  HiddenPage := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), '', '', True, 'Apache');
  HiddenPage.Add('');
  HiddenPage.OnShouldSkipPage := @SkipPage;
end;

该代码需要Inno Setup的Unicode版本。奇怪地调用HiddenPage.Buttons[0].OnClick在Ansi版本中不起作用。

1
投票

为了将来参考，这里是基于Martin的答案的完整工作代码。确保在[Setup]部分添加“DisableDirPage = yes”。

注意：由于存在错误，以下代码仅适用于InnoSetup的unicode版本。

[Code]
var
  DirPage: TInputDirWizardPage;
  HiddenPage: TInputDirWizardPage;
  HiddenPage2: TInputDirWizardPage;
  HiddenPage3: TInputDirWizardPage;

procedure AppendDirBrowseClick(Sender: TObject);
begin
  HiddenPage.Values[0] := DirPage.Values[0];
  HiddenPage.Buttons[0].OnClick(HiddenPage.Buttons[0]);
  DirPage.Values[0] := HiddenPage.Values[0];
end;

procedure AppendDirBrowseClick2(Sender: TObject);
begin
  HiddenPage2.Values[0] := DirPage.Values[1];
  HiddenPage2.Buttons[0].OnClick(HiddenPage2.Buttons[0]);
  DirPage.Values[1] := HiddenPage2.Values[0];
end;

procedure AppendDirBrowseClick3(Sender: TObject);
begin
  HiddenPage3.Values[0] := DirPage.Values[2];
  HiddenPage3.Buttons[0].OnClick(HiddenPage3.Buttons[0]);
  DirPage.Values[2] := HiddenPage3.Values[0];
end;

function SkipPage(Sender: TWizardPage): Boolean;
begin
  Result := True;
end;

procedure InitializeWizard();
begin
  DirPage := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), '', '', False, '');

  DirPage.Add('Path to Apache:');
  DirPage.Add('Path to PHP:');
  DirPage.Add('Path to Server Files:');

  { assign default directories for the items from the previously stored data; if }
  { there are no data stored from the previous installation, use default folders }
  { of your choice }
  DirPage.Values[0] := GetPreviousData('Directory1', 'C:\Apache');
  DirPage.Values[1] := GetPreviousData('Directory2', 'C:\PHP');
  DirPage.Values[2] := GetPreviousData('Directory3', 'C:\Apache\htdocs\Server Files');

  DirPage.Buttons[0].OnClick := @AppendDirBrowseClick;
  DirPage.Buttons[1].OnClick := @AppendDirBrowseClick2;
  DirPage.Buttons[2].OnClick := @AppendDirBrowseClick3;

  HiddenPage := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), '', '', True, 'Apache');
  HiddenPage.Add('');
  HiddenPage.OnShouldSkipPage := @SkipPage;

  HiddenPage2 := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), '', '', True, 'PHP');
  HiddenPage2.Add('');
  HiddenPage2.OnShouldSkipPage := @SkipPage;

  HiddenPage3 := CreateInputDirPage(
    wpSelectDir, SetupMessage(msgWizardSelectDir), '', '', True, 'Server Files');
  HiddenPage3.Add('');
  HiddenPage3.OnShouldSkipPage := @SkipPage;
end;
最新问题
© www.soinside.com 2019 - 2024. All rights reserved.