选中另一个任务时取消选中 Inno Setup 任务

Question

我试图拦截

WizardForm.TasksList.OnClickCheck

事件，以便在选择另一个任务时可以取消选中一个任务。我知道在这种情况下通常会使用单选按钮，但是当选择另一个任务时自动取消选中一个任务在这里效果更好，因为使用了多个分层任务，而且如果使用单选按钮，您总是必须拥有以下之一位于任务子树顶部时选择的两个。为了保持一致性而重新设计任务层次结构是不可行的，因为这将包括两个临时任务，这些任务将在安装程序的未来版本中删除。我写了以下内容来做到这一点：

var
  DefaultTasksClickCheck: TNotifyEvent;

// Uncheck tasks based on what other tasks are selected
procedure UpdateTasks();
var
  intIndex: Integer;
begin
  with WizardForm.TasksList do
    begin
      if IsTaskSelected('Task1') then
        begin
          intIndex := WizardForm.TasksList.Items.IndexOf('Task36 Description');
          CheckItem(intIndex, coUncheck);
        end;
      if IsTaskSelected('Task36') then
        begin
          intIndex := WizardForm.TasksList.Items.IndexOf('Task1 Description');
          CheckItem(intIndex, coUncheck);
        end;
    end;
end;

// Update the task states if the task states change and
// restore the original event handler procedure
procedure TasksClickCheck(Sender: TObject);
begin
  DefaultTasksClickCheck(Sender);
  UpdateTasks;
end;

procedure InitializeWizard();
begin
  // Store the original Tasks Page OnClickCheck event procedure and
  // assign custom procedure
  DefaultTasksClickCheck := WizardForm.TasksList.OnClickCheck;
  WizardForm.TasksList.OnClickCheck := @TasksClickCheck;
end;

但是，当我运行代码时，我得到一个：

超出触发范围

错误，当单击任何复选框时，

DefaultTasksClickCheck(Sender);

突出显示为有问题的行。如果我注释掉这一行，我将不再收到错误，但显然不再恢复原始事件处理程序，并且它仍然无法正确检查和取消选中任务，当检查 Task1 时，Task36 不可检查。我做错了什么？

Answer 1

1. WizardForm.TasksList.OnClickCheck

   不是由Inno Setup本身分配的（与

   WizardForm.ComponentsList.OnClickCheck

   相反），所以你不能调用它。

   要解决该问题，可以：

   • 完全去除

     DefaultTasksClickCheck

     ;
   • 或者如果您希望在 Inno Setup 的未来版本中开始使用该事件时得到保护，请在调用之前检查它是否为

     nil

     。

2. 您无法知道

   OnClickCheck

   处理程序中最近检查了哪些任务。所以你必须记住之前选中的任务才能正确决定取消选择哪个任务。

   [任务] 名称：任务1；描述：“任务1描述” 名称：任务36；描述：“Task36描述”；标志：未选中

[Code]

var
  DefaultTasksClickCheck: TNotifyEvent;
  Task1Selected: Boolean;

procedure UpdateTasks;
var
  Index: Integer;
begin
  // Task1 was just checked, uncheck Task36
  if (not Task1Selected) and IsTaskSelected('Task1') then
  begin
    Index := WizardForm.TasksList.Items.IndexOf('Task36 Description');
    WizardForm.TasksList.CheckItem(Index, coUncheck);
    Task1Selected := True;
  end
    else 
  // Task36 was just checked, uncheck Task1
  if Task1Selected and IsTaskSelected('Task36') then
  begin
    Index := WizardForm.TasksList.Items.IndexOf('Task1 Description');
    WizardForm.TasksList.CheckItem(Index, coUncheck);
    Task1Selected := False;
  end;
end;

procedure TasksClickCheck(Sender: TObject);
begin
  if DefaultTasksClickCheck <> nil then
    DefaultTasksClickCheck(Sender);
  UpdateTasks;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpSelectTasks then
  begin
    // Only now is the task list initialized, check what is the current state
    // This is particularly important during upgrades,
    // when the task does not have its default state
    Task1Selected := IsTaskSelected('Task1');
  end;
end;

procedure InitializeWizard();
begin
  DefaultTasksClickCheck := WizardForm.TasksList.OnClickCheck;
  WizardForm.TasksList.OnClickCheck := @TasksClickCheck;
end;

在 Inno Setup 6 中，除了使用索引之外，您还可以通过

WizardIsTaskSelected

和

WizardSelectTasks

来使用任务名称。有关示例，请参阅 Inno Setup：如果选择了另一个组件，如何自动选择一个组件？。

---

有关检测已检查项目的更通用解决方案，请参阅 检测 TasksList.OnClickCheck 事件中更改的 Inno Setup 任务/项目