generateReleaseBuildConfig在库中出错

Question

Android Studio项目。我有两个库模块，它们都没有任何Java。我正在尝试抑制BuildConfig生成，因此也没有生成Java。第一个的gradle文件是：

apply plugin: 'com.android.library'

android {
    compileSdkVersion 26

    defaultConfig {
        minSdkVersion 3
        targetSdkVersion 26

        externalNativeBuild {
            ndkBuild {
                abiFilters "armeabi", "x86", "x86_64", "armeabi-v7a", "mips", "arm64-v8a"
                targets "pad", "gif"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
        }
        debug {
            jniDebuggable true
        }
    }

    externalNativeBuild {
        ndkBuild {
            path file("src/main/jni/Android.mk")
        }
    }
}

dependencies {}

afterEvaluate {
    generateReleaseBuildConfig.enabled = false
    generateDebugBuildConfig.enabled = false
}

对于另一个：

apply plugin: 'com.android.library'

android {
    compileSdkVersion 26

    defaultConfig {
        minSdkVersion 3
        targetSdkVersion 26

        externalNativeBuild {
            ndkBuild {
                abiFilters "armeabi", "x86", "x86_64", "armeabi-v7a", "mips", "arm64-v8a"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
        }
        debug {
            jniDebuggable true
        }
    }

    externalNativeBuild {
        ndkBuild {
            path file("src/main/jni/Android.mk")
        }
    }

    flavorDimensions 'Color'
    productFlavors {
        Blue {
            dimension "Color"
            externalNativeBuild {
                ndkBuild {
                    cppFlags "-DBLUE"
                }
            }
        }
        Red {
            dimension "Color"
            externalNativeBuild {
                ndkBuild {
                    cppFlags "-DRED"
                }
            }
        }
    }
}

dependencies {
    implementation project(':Foo')
}

afterEvaluate {
    generateReleaseBuildConfig.enabled = false
    generateDebugBuildConfig.enabled = false
}

第一个工作了一段时间，没问题。第二个，我今天创建的，Gradle同步就失败了：

配置项目'：LibBar'时出现问题。

无法为org.gradle.api.Project类型的项目'：LibBar'获取未知属性'generateReleaseBuildConfig'。

如果我评论该线，它抱怨generateDebugBuildConfig。

第二个模块取决于第一个模块，不确定它是否重要。

除了package之外，两者都有一个清单。

我错过了什么？我试过清理项目，使缓存无效。 Gradle是最新版本，Android Studio也是最新版本（刚刚更新）。

Answer 1

构建系统使用当前构建flavor来装饰步骤名称。所以它应该是：

afterEvaluate {
    generateBlueReleaseBuildConfig.enabled = false
    generateBlueDebugBuildConfig.enabled = false
    generateRedReleaseBuildConfig.enabled = false
    generateRedDebugBuildConfig.enabled = false
}