如何在具有透明度和不透明度的画布上绘画？

Question

概述

从 GR32 库中，我使用 TImgView32 渲染网格，这将是我的透明背景，如下所示：

放置在 TImgView32 内，我有一个常规的 TImage，我将在其中在画布上绘图，如下所示：

任务

我想要实现的是能够设置画笔的不透明度，从而为我的程序中的图像编辑提供更多可能性。设置画笔的不透明度可以允许不同级别的颜色深度等，而不是绘制一种平面颜色。

我早些时候在搜索时发现了这个问题：Draw opacity ellipse in Delphi 2010 - Andreas Rejbrand 在他对该问题的回答中提供了一些示例。

我已经研究了安德烈亚斯所做的事情，并提出了我自己的简化尝试，但我遇到了一个问题。看看接下来的两张图片，第一张是透明背景，第二张是黑色背景，可以更清楚地显示问题：

如您所见，画笔（圆圈）周围是一个非常烦人的方块，我无法摆脱。所有可见的都是画笔。这是我用来产生这些结果的代码：

procedure DrawOpacityBrush(ACanvasBitmap: TBitmap; X, Y: Integer;
  AColor: TColor; ASize: Integer; Opacity: Integer);
var
  Bmp: TBitmap;
begin
  Bmp := TBitmap.Create;
  try
    Bmp.SetSize(ASize, ASize);
    Bmp.Transparent := False;

    with Bmp.Canvas do
    begin
      Pen.Color := AColor;
      Pen.Style := psSolid;
      Pen.Width := ASize;
      MoveTo(ASize div 2, ASize div 2);
      LineTo(ASize div 2, ASize div 2);
    end;

    ACanvasBitmap.Canvas.Draw(X, Y, Bmp, Opacity);
  finally
    Bmp.Free;
  end;
end;

procedure TForm1.Image1MouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  DrawOpacityBrush(Image1.Picture.Bitmap, X, Y, clRed, 50, 85);
end;

在常规位图上生成此内容：

我的想法（基于 Andreas 创建具有不透明度的椭圆的方法）是在画布上渲染典型的画笔，将其分配给屏幕外位图，然后将其重新绘制到具有不透明度的主位图上。哪个有效，除了边缘周围那个烦人的方块。

如何渲染具有不透明度的画笔（如屏幕截图所示），但画笔圆圈周围没有正方形？

如果我设置

Bmp.Transparent := True

，仍然有一个白色框，但不再不透明。只是一个实心白色正方形和实心红色圆圈。

Answer 1

TCanvas.Draw()

的不透明度功能不支持您想要做的事情，至少不支持您尝试使用它的方式。 要实现您想要的效果，您需要创建一个 32 位

TBitmap

，这样您就有一个每像素 Alpha 通道，然后填充每个像素的 Alpha，将您不需要的像素的 Alpha 设置为 0，并将 alpha 设置为您想要的像素所需的不透明度。 然后，在调用

TCanvas.Draw()

时，将其不透明度设置为 255 以告诉它仅使用每像素不透明度。

procedure DrawOpacityBrush(ACanvas: TCanvas; X, Y: Integer; AColor: TColor; ASize: Integer; Opacity: Byte);
var
  Bmp: TBitmap;
  I, J: Integer;
  Pixels: PRGBQuad;
  ColorRgb: Integer;
  ColorR, ColorG, ColorB: Byte;
begin
  Bmp := TBitmap.Create;
  try
    Bmp.PixelFormat := pf32Bit; // needed for an alpha channel
    Bmp.SetSize(ASize, ASize);

    with Bmp.Canvas do
    begin
      Brush.Color := clFuchsia; // background color to mask out
      ColorRgb := ColorToRGB(Brush.Color);
      FillRect(Rect(0, 0, ASize, ASize));
      Pen.Color := AColor;
      Pen.Style := psSolid;
      Pen.Width := ASize;
      MoveTo(ASize div 2, ASize div 2);
      LineTo(ASize div 2, ASize div 2);
    end;

    ColorR := GetRValue(ColorRgb);
    ColorG := GetGValue(ColorRgb);
    ColorB := GetBValue(ColorRgb);

    for I := 0 to Bmp.Height-1 do
    begin
      Pixels := PRGBQuad(Bmp.ScanLine[I]);
      for J := 0 to Bmp.Width-1 do
      begin
        with Pixels^ do
        begin
          if (rgbRed = ColorR) and (rgbGreen = ColorG) and (rgbBlue = ColorB) then
            rgbReserved := 0
          else
            rgbReserved := Opacity; 
          // must pre-multiply the pixel with its alpha channel before drawing
          rgbRed := (rgbRed * rgbReserved) div $FF;
          rgbGreen := (rgbGreen * rgbReserved) div $FF;
          rgbBlue := (rgbBlue * rgbReserved) div $FF;
        end;
        Inc(Pixels);
      end;
    end;

    ACanvas.Draw(X, Y, Bmp, 255);
  finally
    Bmp.Free;
  end;
end;

procedure TForm1.Image1MouseDown(Sender: TObject; Button: TMouseButton;  
  Shift: TShiftState; X, Y: Integer);  
begin  
  DrawOpacityBrush(Image1.Picture.Bitmap.Canvas, X, Y, clRed, 50, 85);  
end;