nasm 汇编linux定时器或睡眠

Question

我正在尝试找到一种方法让我的代码在继续之前等待两秒钟。我在保护模式下使用Linux的nasm，所以我只能使用int 80h。我发现了一个

syscall

称为“

alarm

”（27），另一个称为“

pause

”（29）。但是，当我尝试使用它们时，程序会等待并完成，而不是继续执行。我还发现了另一个

syscall

，sigaction，它改变了信号的行为（所以我认为它可以用来让程序忽略alarm生成的信号而不是退出），但我不太明白sigaction是如何实现的作品。感谢您的任何帮助。 有用的链接：http://man7.org/linux/man-pages/man2/alarm.2.html http://man7.org/linux/man-pages/man2/sigaction.2.html

Answer 1

有一个让程序休眠的系统调用，

sys_nanosleep

:

 sys_nanosleep : eax = 162, ebx = struct timespec *, ecx = struct timespec *

这个

struct timespec

结构有两个成员：

 ;; This is for 32-bit.  Note that x86-64 uses 2x 64-bit members
tv_sec   ; 32 bit seconds
tv_nsec  ; 32 bit nanoseconds

这个结构可以在 nasm 中声明为：

section .data

  timeval:
    tv_sec  dd 0
    tv_nsec dd 0

然后设置值并将其称为：

mov dword [tv_sec], 5
mov dword [tv_nsec], 0
mov eax, 162
mov ebx, timeval
mov ecx, 0
int 0x80

程序将休眠 5 秒。一个完整的例子：

global  _start

section .text
_start:

  ; print "Sleep"
  mov eax, 4
  mov ebx, 1
  mov ecx, bmessage
  mov edx, bmessagel
  int 0x80

  ; Sleep for 5 seconds and 0 nanoseconds
  mov dword [tv_sec], 5
  mov dword [tv_nsec], 0
  mov eax, 162
  mov ebx, timeval
  mov ecx, 0
  int 0x80

  ; print "Continue"
  mov eax, 4
  mov ebx, 1
  mov ecx, emessage
  mov edx, emessagel
  int 0x80

  ; exit
  mov eax, 1
  mov ebx, 0
  int 0x80

section .data

  timeval:
    tv_sec  dd 0
    tv_nsec dd 0

  bmessage  db "Sleep", 10, 0
  bmessagel equ $ - bmessage

  emessage  db "Continue", 10, 0
  emessagel equ $ - emessage

Answer 2

使用 NASM，如果您的目标是 Linux x86-64，您可以简单地执行类似于以下的操作：

global _start

section .data

    timespec:
        tv_sec  dq 1
        tv_nsec dq 200000000

section .text

    _start:
        mov rax, 35
        mov rdi, timespec
        xor rsi, rsi        
        syscall
        ...

35

对应于

sys_nanosleep

的 64 位系统调用号（如此处所列）。如果调用中断，则将剩余睡眠时间写入寄存器

rsi

指向的内存位置；在此示例中，

rsi

设置为 0 以忽略该值（如果发生）。此调用将休眠 tv_sec 秒 + tv_nsec 纳秒，即上述代码片段中的 1.2 秒。

有关此系统调用的更多信息可以在 nanosleep 手册页中找到。