使用XSLT转换XML数据

Question

我有以下xml数据

<UserStaging>
            <NeuroRKStaging>
               <Stage Type="REM" Start="0" />
               <Stage Type="Stage3" Start="150" />
               <Stage Type="Movement" Start="3030" />
               <Stage Type="Wake" Start="3150" />
               <Stage Type="Stage2" Start="4680" />
               <Stage Type="Stage3" Start="5340" />
               <Stage Type="Movement" Start="6090" />
               <Stage Type="Wake" Start="6480" />
               <Stage Type="Stage1" Start="9330" />
               <Stage Type="Stage3" Start="10290" />
            </NeuroRKStaging>
</UserStaging>

我必须得到以下格式：

REM 150
N2 3150
Wake 4680
N2 5340
N3 6480
Wake 9330
N1 10290
N3 50000

有五种“类型”：

Stage1 transforms to N1
Stage2 transforms to N2
Stage3 transforms to N3
REM remains REM
Wake remains Wake

应删除所有具有Type =“Movement”的行，并且仅在此之后才应转换数据。每个后续阶段的“开始”将是它之前的“类型”背后的数字。对于最后一个“类型”（在这个例子中为N3），数字应为50000

xsl样式表怎么样？我可以使用XSLT版本3.感谢您的帮助！

Answer 1

您可以使用以下脚本：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="Stage[@Type = 'Movement']"/>

  <xsl:template match="@Type[matches(., 'Stage')]">
    <xsl:value-of select="concat('N', substring(., 6))"/>
  </xsl:template>

  <xsl:template match="Stage">
    <xsl:apply-templates select="@Type"/>
    <xsl:variable name="nxtStart" select="
      (following-sibling::*[not(@Type = 'Movement')][1]/@Start, 50000)[1]"/>
    <xsl:value-of select="concat(' ', $nxtStart, '&#xA;')"/>
  </xsl:template>
</xsl:stylesheet>

匹配Stage[@Type = 'Movement']的模板过滤掉Type =“Movement”的行。

下一个模板，匹配@Type[matches(., 'Stage')]执行Stage到N的翻译。

最后，最后一个模板，匹配Stage做主要工作。它：

• 打印（可能已更改）Type属性的值。
• 计算在下一个兄弟中包含nxtStart属性的变量（Start），但不包括那些带有Type = 'Movement'的变量，但如果不存在，则“代理”值为50000。
• 打印应该打印的其余部分。