如何从外部委托读取父ListView的自定义属性？

Question

我有一个ListView及其在其他qml文件中定义的委托。

main.qml：

import QtQuick 2.12
import QtQuick.Window 2.12

Window {
    visible: true
    width: 640
    height: 480

    ListModel {
        id: listModel
        ListElement {
            name: "Bill Smith"
        }
        ListElement {
            name: "John Brown"
        }
        ListElement {
            name: "Sam Wise"
        }
    }

    ListView {
        width: 180; height: 200
        property color delegateColor: "green"

        model: listModel
        delegate: ExternalDelegate {}
    }
}

ExternalDelegate.qml：

import QtQuick 2.12
import QtQuick.Controls 2.12

ItemDelegate {

    background: Rectangle {
        color: ListView.view.delegateColor
    }

    Text {
        text: model.name
    }
}

父级ListView具有自定义属性委托颜色。我需要从委托中读取此属性。但是，如果我尝试通过附加属性ListView.view访问它，则它将无法正常工作。我在控制台中看到消息：

qrc:/ExternalDelegate.qml:7: TypeError: Cannot read property 'delegateColor' of null

如何从外部委托读取ListView的自定义属性？

我需要在ListView中设置此属性（而不是在委托中），因为我也想从页眉，页脚和节委托中访问此属性。

Answer 1

在这种情况下，最好不要让组件知道它们的用途，而是通过根元素的属性来公开它们，例如，可以创建矩形颜色的别名，在这种情况下，文本ItemDelegate组件已经具有该属性。

import QtQuick 2.12
import QtQuick.Controls 2.12

ItemDelegate {
    id: root
    property alias color: bg.color
    background: Rectangle {
        id: bg
    }
    contentItem: Text {
        text: root.text
    }
}

delegate: ExternalDelegate {
    text: model.name
    color: ListView.view.delegateColor
}

另一种解决方案是仅更改新属性的别名：

import QtQuick 2.12
import QtQuick.Controls 2.12

ItemDelegate {
    id: root
    property color color : "white"
    background: Rectangle {
        color: root.color
    }
    contentItem: Text {
        text: root.text
    }
}