将映射转换为结构体

Question

我正在尝试将映射转换为结构，如下所示：

我有地图：

iex(6)> user                      
%{"basic_auth" => "Basic Ym1hOmphYnJhMTc=", "firstname" => "foo",
  "lastname" => "boo"}

该值应应用于结构：

iex(7)> a = struct(UserInfo, user)
%SapOdataService.Auth.UserInfo{basic_auth: nil, firstname: nil, lastname: nil}

正如你所看到的，struct 的值是 nil，为什么？

Answer 1

要扩展 JustMichael 的答案，您可以首先使用

String.to_existing_atom/1

将键转换为原子，然后使用

Kernel.struct/2

构建结构：

user_with_atom_keys = for {key, val} <- user, into: %{} do
  {String.to_existing_atom(key), val}
end

user_struct = struct(UserInfo, user_with_atom_keys)
# %UserInfo{basic_auth: "Basic Ym1hOmphYnJhMTc=", firstname: "foo",
 lastname: "boo"}

请注意，这使用

String.to_existing_atom/1

来防止 VM 达到全局 Atom 限制。

Answer 2

你可以尝试exconstructor。它完全满足您的需要。

这是一个小例子：

defmodule TestStruct do
  defstruct field_one: nil,
            field_two: nil,
            field_three: nil,
            field_four: nil
  use ExConstructor
end

TestStruct.new(%{"field_one" => "a", "fieldTwo" => "b", :field_three => "c", :FieldFour => "d"})
# => %TestStruct{field_one: "a", field_two: "b", field_three: "c", field_four: "d"}

文档链接：http://hexdocs.pm/exconstructor/ExConstructor.html

Answer 3

为此我将使用 Ecto 的变更集：

defmodule UserInfo do
  use Ecto.Schema

  schema "user_info" do
    field :basic_auth, :string
    field :firstname, :string
    field :lastname, :string
  end
end

然后在代码中的某个地方

import Ecto.Changeset

user_struct = cast(%UserInfo{}, 
                   your_user_map, 
                   UserInfo.__schema__(:fields)) 
              |> apply_changes

使用 ecto 的好处是，您还可以获得验证等额外好处，并且不必担心映射中的字段是字符串或原子。

Answer 4

我的疯狂猜测是它不起作用，因为你的键在映射中是字符串，在结构中是原子。

Answer 5

  %{"basic_auth" => "Basic Ym1hOmphYnJhMTc=", "firstname" => "foo", "lastname" => "boo"}
  |> Poison.encode
  |> (fn {:ok, json} -> json end).()
  |> Poison.decode(as: %SapOdataService.Auth.UserInfo{})

或

  ~S({"basic_auth":"Basic Ym1hOmphYnJhMTc=","firstname":"foo","lastname":"boo"})
  |> Poison.decode(as: %SapOdataService.Auth.UserInfo{})

请注意，这不会与

@enforce_keys

上的

UserInfo

一起编译。

Answer 6

%User{username: "test"} = struct(User, %{username: "test", password: "secret"})

来自 https://elixir-examples.github.io/examples/map-to-struct