为什么我在GLSL着色器中看到这些混合工件？

Question

我正在尝试创建一个着色器，将着色的“blob”（有点像粒子）叠加在一起。这似乎应该是一个简单的任务，但是当blob混合时，我会变得奇怪的“条纹”式的文物。

首先，这是我所追求的行为（使用Photoshop图层复制）：

请注意，三个颜色层都设置为blendmode“Linear Dodge（Add）”，据我所知，这是Photoshop的“添加”混合模式。

如果我合并颜色图层并将生成的图层设置为“正常”混合，我可以随意更改背景颜色。

显然，添加混合不会在非黑色背景上工作，所以最后我还需要/需要着色器支持这种颜色的预合并，然后最终混合到可能有任何颜色的背景中。但是，我现在满足于只专注于使黑色混合添加剂正常工作，因为它不是。

这是我当前状态下的着色器代码。

const int MAX_SHAPES = 10;
vec2 spread = vec2(0.3, 0.3);
vec2 offset = vec2(0.0, 0.0);
float shapeSize = 0.3;
const float s = 1.0;
float shapeColors[MAX_SHAPES * 3] = float[MAX_SHAPES * 3] (
  s, 0.0, 0.0,
  0.0, s, 0.0,
  0.0, 0.0, s,
  s, 0.0, 0.0,
  s, 0.0, 0.0,
  s, 0.0, 0.0,
  s, 0.0, 0.0,
  s, 0.0, 0.0,
  s, 0.0, 0.0,
  s, 0.0, 0.0
);

vec2 motionFunction (float i) {
  float t = iTime;

  return vec2(
    (cos(t * 0.31 + i * 3.0) + cos(t * 0.11 + i * 14.0) + cos(t * 0.78 + i * 30.0) + cos(t * 0.55 + i * 10.0)) / 4.0,
    (cos(t * 0.13 + i * 33.0) + cos(t * 0.66 + i * 38.0) + cos(t * 0.42 + i * 83.0) + cos(t * 0.9 + i * 29.0)) / 4.0
  );
}

float blend (float src, float dst, float alpha) {
  return alpha * src + (1.0 - alpha) * dst;
}

void mainImage (out vec4 fragColor, in vec2 fragCoord) {
    float aspect = iResolution.x / iResolution.y;
    float x = (fragCoord.x / iResolution.x) - 0.5;
    float y = (fragCoord.y / iResolution.y) - 0.5;
    vec2 pixel = vec2(x, y / aspect);

    vec4 totalColor = vec4(0.0, 0.0, 0.0, 0.0);
    for (int i = 0; i < MAX_SHAPES; i++) {
        if (i >= 3) {
            break;
        }

        vec2 shapeCenter = motionFunction(float(i));

        shapeCenter *= spread;
        shapeCenter += offset;
        float dx = shapeCenter.x - pixel.x;
        float dy = shapeCenter.y - pixel.y;
        float d = sqrt(dx * dx + dy * dy);
        float ratio = d / shapeSize;
        float intensity = 1.0 - clamp(ratio, 0.0, 1.0);
        totalColor.x = totalColor.x + shapeColors[i * 3 + 0] * intensity;
        totalColor.y = totalColor.y + shapeColors[i * 3 + 1] * intensity;
        totalColor.z = totalColor.z + shapeColors[i * 3 + 2] * intensity;
        totalColor.w = totalColor.w + intensity;
    }

    float alpha = clamp(totalColor.w, 0.0, 1.0);
    float background = 0.0;
    fragColor = vec4(
        blend(totalColor.x, background, alpha),
        blend(totalColor.y, background, alpha),
        blend(totalColor.z, background, alpha),
        1.0
    );
}

这是一个ShaderToy版本，你可以在那里查看它 - https://www.shadertoy.com/view/wlf3RM或视频 - https://streamable.com/un25t

视觉工件应该是非常明显的，但这里有一个视频指出它们：https://streamable.com/kxaps（我认为它们在这个之前链接的视频中更流行。但是这个动作真的让它们弹出来了。）

另外作为静态图像进行比较：

基本上，在某些神奇的阈值上会出现“边缘”。我不知道他们是如何到达那里或如何摆脱他们。非常感谢您的帮助。

Answer 1

内线是totalColor.w达到1的地方，因此alpha被夹在其中1。你用白色描绘的外部是圆圈的边缘。

我通过将float alpha = clamp(totalColor.w, 0.0, 1.0);更改为float alpha = 1.0;并将float intensity = 1.0 - clamp(ratio, 0.0, 1.0);更改为float intensity = smoothstep(1.0, 0.0, ratio);（以平滑圆圈的边缘）来修改您的ShaderToy链接，现在它看起来像第一张图片。