在Perl中将字符串“a.b.c”转换为$ hash - > {a} - > {b} - > {c}

Question

我有这样的动态嵌套哈希引用：

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } };

我想通过允许用户输入“a.b.c something”来将c的值设置为'something'。

现在可以像这样获得价值：

my $keys = 'a.b.c'; 
my $v='something';
my $h = $hash;
foreach my $k(split /\./, $keys) {
  $h = $h->{$k};
}
print $h; # "value"

但是，如何将关键c的值设置为$v

print Dumper $hash;

会反映出这种变化吗？ $h在foreach循环结束时不是ref，所以改变它不会反映$hash的变化。任何提示如何解决我头上的结？

Answer 1

像这样的东西：

my $h = $hash;
my @split_key = split /\./, $keys;
my $last_key = pop @split_key;
foreach my $k (@split_key) {
    $h = $h->{$k};
}
$h->{$last_key} = $v;

Answer 2

sub dive_val :lvalue {
   my $p = \shift;
   $p = \( ($$p)->{$_} ) for @_;
   return $$p;
}

my $data;
my $key = 'a.b.c';
my $val = 'value';

dive_val($data, split /\./, $key) = $val;

Data::Diver提供了这个函数的更强大（因此稍微难以使用）的版本。

use Data::Diver qw( DiveVal );

my $data;
my $key = 'a.b.c';
my $val = 'value';

DiveVal($data //= {}, map \$_, split /\./, $key) = $val;

（daxim的用法略有偏差。）

Answer 3

use strictures;
use Data::Diver qw(DiveVal);

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } },
    'a.b.c',
    'something',
);

DiveVal($hash, split /[.]/, $path) = $value;
# { a => { b => { c => 'something' } } }