GLSL中阴影射线的平滑阴影无法正常工作

Question

我正在WebGL中实现具有网格点的光线跟踪器。我的实施很少说。

我在纹理中传递顶点值和顶点法线，然后在执行光线跟踪算法的片段着色器中解压缩它们。由三角形组成的球体具有平面阴影外观，然后我将三角形的顶点法线与重心坐标相乘，并且我在三角​​形球体中具有平滑的外观。问题是当我计算阴影时，它具有相同的“前卫”外观。我提供结果的打印屏幕和我当前如何计算阴影射线的代码。

如您所见，球体表面看起来很光滑，但阴影却没有。

这是我使用的calcShadow函数：

vec3 calcShadow(Sphere lightSource, vec3 hitPos){
    vec3 color;

    vec3 lightDir =  normalize(lightSource.center-hitPos);
    Ray shadowRay = Ray(hitPos, lightDir);

    float isHitLight = hitLightSource(shadowRay,lightSource);
    float isHitMesh = hitMesh(shadowRay);

    if (isHitMesh < isHitLight) {
        color = vec3(0.5,0.5,0.5);
    }else{
        color = vec3(1.,1.,1.);    
    }
    return color;
}

hitMesh：

float hitMesh(Ray R_){
    float mindist = 1000.;
    vec4 a = vec4(0.0), b = vec4(0.0), c = vec4(0.0);
    vec3 intersect = vec3(0.0,0.0,0.0);

    for (int i = 0; i < vertsCount; i += 3) {
        a = texelFetch(uMeshData, ivec2(i, 0), 0);
        b = texelFetchOffset(uMeshData, ivec2(i, 0), 0, ivec2(1, 0));
        c = texelFetchOffset(uMeshData, ivec2(i, 0), 0, ivec2(2, 0));

        vec3 triangleNormal;
        vec3 uvt;
        float z;

        bool isHit = hitTriangleSecond(R_.orig, R_.dir, a.xyz, b.xyz, c.xyz, uvt, triangleNormal, intersect, z);;
        if (isHit) {
            if (z<mindist && z > 0.001)  mindist = z;
        } 

    }
    return mindist;
}

这是三角交叉测试的hitTriangke第二种方法：

bool hitTriangleSecond( vec3 orig, vec3 dir, vec3 a, vec3 b, vec3 c,
                        out vec3 uvt, out vec3 N, out vec3 x, out float dist) {

    float eps=1e-8;

    vec3 ab = b - a;
    vec3 ac = c - a;

    N = normalize(cross(ab, ac));

    dist = dot(a - orig, N) / dot(dir, N);
    x    = orig + dir * dist;

    vec3 ax = x - a;

    float d00 = dot(ab, ab);
    float d01 = dot(ab, ac);
    float d11 = dot(ac, ac);
    float d20 = dot(ax, ab);
    float d21 = dot(ax, ac);

    float denom = d00 * d11 - d01 * d01; // determinant

    // if the determinant is negative the triangle is backfacing
    // if the determinant is close to 0, the ray misses the triangl
    if ( denom <= eps )
        return false;

    uvt.y = (d11 * d20 - d01 * d21) / denom;
    if ( uvt.y < 0.0 || uvt.y > 1.0 )
        return false;

    uvt.z = (d00 * d21 - d01 * d20) / denom;
    if ( uvt.z < 0.0 || uvt.z > 1.0 )
        return false;

    uvt.x = 1.0 - uvt.y - uvt.z;
    if ( uvt.x < 0.0 || uvt.x > 1.0 )
        return false;

    return true;
}

我知道没有计算插值三角形法线，但我的问题是，我是否需要更新hitTriangle函数以返回基于顶点法线的插值法线？或者我需要计算重心坐标，然后将其插入到三角形函数中？我有点不明白如何实现平滑阴影......

下面是我的循环跟踪，我解压缩网格并计算命中的插值法线，这就是我得到光滑表面外观的方法：

for (int i = 0; i < vertsCount; i += 3) {

            a = texelFetch(uMeshData, ivec2(i, 0), 0);
            b = texelFetchOffset(uMeshData, ivec2(i, 0), 0, ivec2(1, 0));
            c = texelFetchOffset(uMeshData, ivec2(i, 0), 0, ivec2(2, 0));

            aN = texelFetch(uNormData, ivec2(i, 0), 0);
            bN = texelFetchOffset(uNormData, ivec2(i, 0), 0, ivec2(1, 0));
            cN = texelFetchOffset(uNormData, ivec2(i, 0), 0, ivec2(2, 0));

            vec3 uvt;
            vec3 intersect;
            float z;
            bool isHit = hitTriangleSecond(R_.orig, R_.dir, a.xyz, b.xyz, c.xyz, uvt, triangleNormal, intersect, z);
            if (isHit) {

                if (z<mindist && z > 0.001) {
                    hitPos1 = intersect;

                    mindist = z;
                    weHitSomething = true;
                    material.type = DIEL;
                    material.albedo = vec3(.8, .3, .4);
                    normal = aN.xyz*uvt.x + bN.xyz*uvt.y + cN.xyz*uvt.z;

                    hitPos = hitPos1;            
                }
            }      
        } 

Answer 1

用于射线命中测试的网格仍然是低分辨率三角形网格，即使您使用法线来纠正光照计算，因此阴影中的尖角也有所预期。

光线投射依赖于三角形交叉，因此对于平滑阴影，您需要在阴影施法者中使用平滑几何体 - 即更多三角形。像法线贴图这样的技术可以用于照明，因为您可以根据修改的方向伪造近似光强度，但实际上没有任何表面位移可以改变物理几何形状，因此无法纠正任何不正确的命中测试。

阴影真正需要的是更多几何体，以便您使用真实三角形准确描述阴影投射轮廓边的形状。