来自四个角 glsl 的噪声混合

Question

我正在研究来自 bookofshaders 的噪声，在 2d 噪声中，这是书籍或网站中的代码。

#ifdef GL_ES
precision mediump float;
#endif

uniform vec2 u_resolution;
uniform vec2 u_mouse;
uniform float u_time;

// 2D Random
float random (in vec2 st) {
    return fract(sin(dot(st.xy,
                         vec2(12.9898,78.233)))
                 * 43758.5453123);
}

// 2D Noise based on Morgan McGuire @morgan3d
// https://www.shadertoy.com/view/4dS3Wd
float noise (in vec2 st) {
    vec2 i = floor(st);
    vec2 f = fract(st);

    // Four corners in 2D of a tile
    float a = random(i);
    float b = random(i + vec2(1.0, 0.0));
    float c = random(i + vec2(0.0, 1.0));
    float d = random(i + vec2(1.0, 1.0));

    // Smooth Interpolation

    // Cubic Hermine Curve.  Same as SmoothStep()
    vec2 u = f*f*(3.0-2.0*f);
    // u = smoothstep(0.,1.,f);

    // Mix 4 coorners percentages
    return mix(a, b, u.x) +
            (c - a)* u.y * (1.0 - u.x) +
            (d - b) * u.x * u.y;
}

void main() {
    vec2 st = gl_FragCoord.xy/u_resolution.xy;

    // Scale the coordinate system to see
    // some noise in action
    vec2 pos = vec2(st*5.0);

    // Use the noise function
    float n = noise(pos);

    gl_FragColor = vec4(vec3(n), 1.0);
}

这段代码中有一些我无法理解的事情

1. 为什么所有角点的混合或组合噪声值都有这样的计算

     mix(a, b, u.x) + (c - a)* u.y * (1.0 - u.x) + (d - b) * u.x * u.y;
   

从最初的理解来看，很容易猜测一切都是线性插值，但我无法理解为什么

u.y*(1.0-u.x)

和

u.x*u.y

被用作因子。

是否有人选择了这种特定的方式，并且没有具体的原因为什么专门这样做，或者这种混合不是标准的混合方式，但人们可以随心所欲地混合？

2. 并在代码行中

    vec2 pos = vec2(st*5.0)
   

我无法理解这如何增加噪音的频率。

任何人都可以帮我理解这一点吗？

Answer 1

对于问题1，

这个方程只是

的复杂版本

float a1 = mix(a, b, u.x);
float b1 = mix(c, d, u.x);
return mix(a1, b1, u.y);

谢谢你